Replacing a character in keys in an object

[jonlarsdizparc]

Currently have a bit of trouble with the following scenario:

• A variable is created that contain secrets:

  var secrets = { 
    database-name: database_name
    database-server: '${database_server}${environment().suffixes.sqlServerHostname}'
  }

• This object is later used to populate a key vault:

   resource key_vault 'Microsoft.KeyVault/vaults@2024-04-01-preview' = {
     name: key_vault_name
     location: 'westeurope'
     properties: {
       accessPolicies: []
       publicNetworkAccess: 'Enabled'
       sku: {
         family: 'A'
         name: 'standard'
       }
       tenantId: tenant_id
     }
  
     // Secrets
     resource key_vault_secrets 'secrets' = [for secret in items(secrets): {
       name: secret.key
       properties: {value: secret.value}
     }]
   }

• These secrets should then be added to a function app as key vault references. The problem here is we need to change the - character in each key to _ and set the value to be:

  @Microsoft.KeyVault(VaultName=${key_vault_name};SecretName=${secret.key})
  

• We then use the secrets to add them to the function app:

  resource symbolicname 'Microsoft.Web/sites/config@2022-09-01' = {
    name: 'appsettings'
    parent: function_app
    properties: <secrets object with the keys fixed and new value>
  }

How do i do this? Do i create a new variable (array) where i loop each secret , replace the key, insert it into the array and then convert the array back to an object?

Any help is appreciated. Thanks.

[anthony-c-martin]

I think you should be able to use the toObject function to achieve something like the below:

resource symbolicname 'Microsoft.Web/sites/config@2022-09-01' = {
  name: 'appsettings'
  parent: function_app
  properties: toObject(
    items(secrets),
    secret => replace(secret.key, '-', '_'),
    secret => '@Microsoft.KeyVault(VaultName=${key_vault_name};SecretName=${secret.key})')
}

[jonlarsdizparc]

Worked perfectly. Thanks!