parent not working when using module

[davidjhole]

I'm looking for a way to create a subnet later on after I have created a firewall and a udr and getting stuck in a bit of a loop so looking for a solution.
I'm trying to create the subnets separately to the vnet in the hope to add a depends on UDR so the final subnets created after everything else and have got stuck at this point.

Anyway back on to the issue, so the below works fine and deploys the vnet and subnet

resource vnet 'Microsoft.Network/virtualNetworks@2021-02-01'  = {
  name: 'vnet01'
  location: 'UKSouth'
  properties: {
    addressSpace: {
      addressPrefixes: [
        '10.0.0.0/16'
      ]
    }
  }
}
resource subnet 'Microsoft.Network/virtualNetworks/subnets@2021-02-01' = {
  name: 'sub01'
  parent: vnet
 properties: {
   addressPrefix: '10.0.1.0/24'
 }
}

If I try the same thing but use a vnet module it doesn’t even try and create the subnet or error at all.

module vnet2 '../modules/vnet.module.bicep' = {
  name: 'vnet02'
  params: {
    vnetName: 'vnet02'
    addressPrefix: '10.1.0.0/16'
    subnetsDefinitions: []
  }

}

resource subnet2 'Microsoft.Network/virtualNetworks/subnets@2021-02-01' = {
  name: 'sub02'
  parent: vnet2
  properties: {
    addressPrefix: '10.1.1.0/24'
  }
}

vnet.module.bicep

param addressPrefix string = '10.0.0.0/16'
param subnetsDefinitions array = [
  {
    name: 'default'
    subnetPrefix: '10.0.1.0/24'
  }
]
param vnetName string

var subnets = [for subnet in subnetsDefinitions: {
  name: subnet.name
  properties: {
    addressPrefix: subnet.subnetPrefix
  }
}]

resource vnet 'Microsoft.Network/virtualNetworks@2021-02-01' = {
  name: vnetName
  location: resourceGroup().location
  properties: {
    addressSpace: {
      addressPrefixes: [
        addressPrefix
      ]
     }
     subnets: subnets
   }
}

output vnetID string = vnet.id
output subnets array = vnet.properties.subnets

[brwilkinson]

Hi @davidjhole

This is one of the items that is being worked on, in order to make this scenario easier #2246

To explain the current state... via your example:

Parent is not equivalent to Dependson. There is a separate dependsOn property.

When you use parent it expects a resource type reference. The reference to the Module (which can potentially do/contain anything and multiples of them) does not satisfy that reference (or a VNET).

Some the options are:

1. Use this '/' notation to pass in the values for the vnet name and the subnet name via the name property. i.e. don't use the parent property since it's not needed here...

resource subnet2 'Microsoft.Network/virtualNetworks/subnets@2021-02-01' = {
  name: 'vnet02/sub02'
  properties: {
    addressPrefix: '10.1.1.0/24'
  }
}

I noticed that you can also use a reference to the module to retrieve the Module Name string and use that, since/so long as it will match the vnet name. I think this is more scalable.

module vnet2 '../modules/vnet.module.bicep' = {
  name: 'vnet02'
  params: {
    vnetName: 'vnet02'
    addressPrefix: '10.1.0.0/16'
    subnetsDefinitions: []
  }

}

resource subnet2 'Microsoft.Network/virtualNetworks/subnets@2021-02-01' = {
  name: '${vnet2.name}/sub02'
  properties: {
    addressPrefix: '10.1.1.0/24'
  }
}

My personal recommendation would be: Simply update your subnet definitions in your source code to reflect the new state (UDR/RT/NSG) redeploy the whole VNET again which will have the same outcome and overall have less chance of any configuration skew over time.

Looking at this 'sample' it will be deploying the whole VNET and then the SUBNETS a whole second time here anyway, so the second subnet loop is redundant. Assume this may just be a sample for this repro.

Otherwise if you are only wanting to deploy the subnet loop template (maybe for a DR exercise or change window) i.e. independently, then move to an existing resource for the vnet. That way it will ONLY process the subnet loop and not have to execute the VNET module at all.

resource vnet 'Microsoft.Network/virtualNetworks@2021-02-01' existing = {
  name: vnetName
}

resource subnet2 'Microsoft.Network/virtualNetworks/subnets@2021-02-01' = {
  name: 'sub02'
  parent: vnet
  properties: {
    addressPrefix: '10.1.1.0/24'
  }
}

Hopfully that gives you some ideas.

[davidjhole]

Thanks Ben, that certantly pointed me in the right direction, I ended up creating a module to do it so i can then consume that after the inital vnet/firewall/udr creation.

-subnet.module.bicep

param subnetPropertyObject array 
resource subnet 'Microsoft.Network/virtualNetworks/subnets@2021-02-01' = [for sn in subnetPropertyObject: { 
  name: '${sn.parentVnetName}/${sn.name}'
  properties: sn.properties
}]