elasticsearch_docs

#!/usr/bin/env perl

# Parameters supported:
#
# config
# autoconf
#
# Magic markers:
#%# family=auto
#%# capabilities=autoconf

use strict;
use warnings;
use LWP;
use JSON qw/decode_json/;

=head1 NAME

elasticsearch_docs - A munin plugin that collects document stats of your elasticsearch instances

=head1 APPLICABLE SYSTEMS

Elasticsearch

=head1 CONFIGURATION

None

=head1 BUGS

None known so far. If you find any, let me know.

=head1 AUTHOR

Tomas Doran (t0m) - c<< <bobtfish@bobtfish.net> >>
Kentaro Yoshida - https://github.com/y-ken

=cut

my $protocol = exists $ENV{'protocol'} ? $ENV{'protocol'} : 'http';
my $host = exists $ENV{'host'} ? $ENV{'host'} : 'localhost';
my $port = exists $ENV{'port'} ? $ENV{'port'} : 9200;
my $user = exists $ENV{'username'} ? $ENV{'username'} : '';
my $pass = exists $ENV{'password'} ? $ENV{'password'} : '';

my $ua = LWP::UserAgent->new;
$ua->timeout(10);

sub get_json_from_url {
    my $uri = shift;
    my $req = HTTP::Request->new('GET', $uri, ['Content-Type' => 'application/json']);
    if ($user ne '') {
        $req->authorization_basic($user, $pass);
    }
    my $res = $ua->request($req);

    Carp::confess($res->code . " for " . $uri) unless $res->is_success;
    my $data = do { local $@; eval { decode_json($res->content) } };
    die("Could not decode JSON from: " . $res->content) unless $data;
    return $data;
}

my $data = get_json_from_url("$protocol://$host:$port/_nodes");
my $t_data = get_json_from_url("$protocol://$host:$port/_nodes/stats");
my %out = (num_docs => 0);

foreach my $full_node_name (keys %{$data->{nodes}}) {
    next unless $t_data->{nodes}{$full_node_name};
    $out{num_docs} += $t_data->{nodes}{$full_node_name}{indices}{docs}{count};
}

if ($ARGV[0] and $ARGV[0] eq 'config') {
    print "graph_title elasticsearch documents\n";
    print "graph_category elasticsearch\n";

    foreach my $name (keys %out) {
        print "$name.label $name\n"."$name.type GAUGE\n";
    }
}
elsif (!$ARGV[0] || $ARGV[0] eq 'autoconf') {
    foreach my $name (keys %out) {
        print "$name.value " . $out{$name} . "\n";
    }
}

exit(0);