-
Notifications
You must be signed in to change notification settings - Fork 4
/
GEOSBuild.lpr
583 lines (484 loc) · 16.2 KB
/
GEOSBuild.lpr
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
//------------------------------------------------------------------------------
//GEOSBuild
//=========
//Command-line tool that builds a GEOS file on a Commodore 64/128 disk image
//from its constituent parts.
//
//Exit codes:
//-----------
// 0 - Success
//-1 - Help requested
//-2 - Invalid option specified
//-3 - Processing error
//-4 - Unexpected error
//
//Please note:
//------------
//Presently, only FPC/Lazarus is supported.
//
//Copyright (C) 2016, Daniel England.
//All Rights Reserved. Released under the GPL.
//
//This program is free software: you can redistribute it and/or modify it under
//the terms of the GNU General Public License as published by the Free Software
//Foundation, either version 3 of the License, or (at your option) any later
//version.
//
//This program is distributed in the hope that it will be useful, but WITHOUT
//ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
//FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
//details.
//
//You should have received a copy of the GNU General Public License along with
//this program. If not, see <http://www.gnu.org/licenses/>.
//
//------------------------------------------------------------------------------
program GEOSBuild;
{$IFDEF FPC}
{$MODE OBJFPC}
{$ENDIF}
{$H+}
uses
{$IFDEF FPC}
{$IFDEF UNIX}{$IFDEF UseCThreads}
cthreads,
{$ENDIF}{$ENDIF}
{$ENDIF}
Classes, SysUtils, IniFiles, CustApp, C64D64Image;
const
LIT_TOK_GEOSVLIREND = '__VLIR_END';
LIT_TOK_GEOSVLIREMY = '__VLIR_EMPTY';
type
{ TGEOSBuild }
TGEOSBuild = class(TCustomApplication)
private
FDiskImage: TD64Image;
FFileName: string;
FHeaderFile: TMemoryStream;
FDirEntry: TD64DirEntry;
procedure DoWriteBanner(const AInit: Boolean);
procedure DoGEOSSequentialFile(const AIniFile: TIniFile);
procedure DoGEOSVLIRFile(const AIniFile: TIniFile);
protected
procedure DoRun; override;
procedure DoProcessBuildFile(const AFileName: string);
procedure Trace(const AType: TEventType; const AMessage: string);
public
constructor Create(TheOwner: TComponent); override;
destructor Destroy; override;
procedure WriteHelp; virtual;
end;
//dengland To signal processing errors
EGEOSBuildError = class(Exception);
{ TGEOSBuild }
procedure TGEOSBuild.DoWriteBanner(const AInit: Boolean);
begin
if AInit then
begin
Writeln('GEOS Build.');
Writeln(EmptyStr);
end
else
begin
Writeln('GEOS file build tool.');
Writeln('Copyright (c) 2016, Daniel England.');
Writeln('All Rights Reserved. Released under the GPL.');
Writeln(EmptyStr);
Writeln('This program comes with ABSOLUTELY NO WARRANTY; without even' +
' the implied');
Writeln('warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR'+
' PURPOSE. This is free');
Writeln('software and you are welcome to redistribute it under'+
' certain conditions.');
Writeln(EmptyStr);
Writeln('See accompanying documentation for further details.');
Writeln(EmptyStr);
Writeln(EmptyStr);
Writeln(EmptyStr);
end;
end;
procedure TGEOSBuild.DoGEOSSequentialFile(const AIniFile: TIniFile);
var
s: string;
m: TMemoryStream;
sz: Int64;
datt: TD64TrackNum;
dats: TD64SectorNum;
datb: Word;
begin
s:= AIniFile.ReadString('sequential', 'Data', '');
if not FileExists(s) then
raise Exception.Create(
'Error: Data file for Sequential file structure must exist.');
m:= TMemoryStream.Create;
try
m.LoadFromFile(s);
//dengland If the file is a .prg file, then we assume it has the two byte load
// address at the beginning.
if CompareText(ExtractFileExt(s), '.PRG') = 0 then
m.Position:= 2
else
m.Position:= 0;
sz:= m.Size - m.Position;
FDiskImage.AllocateDiskSectors(m, datt, dats, datb);
Trace(etInfo, 'Allocated file data fork of size: ' + IntToStr(sz) +
' (' + IntToStr(datb) + ' blocks)');
FDirEntry.SetDataTS(datt, dats);
FDirEntry.SetFileSize(datb);
finally
m.Free;
end;
end;
procedure TGEOSBuild.DoGEOSVLIRFile(const AIniFile: TIniFile);
var
i: Integer;
m,
f: TMemoryStream;
d: PByte;
rect,
datt: TD64TrackNum;
recs,
dats: TD64SectorNum;
recb,
datb: Word;
s: string;
sz: Int64;
begin
m:= TMemoryStream.Create;
f:= TMemoryStream.Create;
try
m.SetSize(VAL_SIZ_D64SECTRSIZE - 2);
m.Position:= 0;
d:= PByte(m.Memory);
for i:= 0 to 126 do
begin
s:= AIniFile.ReadString('VLIR', IntToStr(i), LIT_TOK_GEOSVLIREMY);
if CompareText(s, LIT_TOK_GEOSVLIREMY) = 0 then
begin
d^:= $00;
Inc(d);
d^:= $FF;
Inc(d);
end
else if CompareText(s, LIT_TOK_GEOSVLIREND) = 0 then
begin
d^:= $00;
Inc(d);
d^:= $00;
Inc(d);
end
else
begin
if not FileExists(s) then
raise EGEOSBuildError.Create('Error: VLIR Record #' +
IntToStr(i)+ ' File Name does not exist.');
f.LoadFromFile(s);
//dengland If the file is a .prg file, then we assume it has the two byte
// load address at the beginning.
if CompareText(ExtractFileExt(s), '.PRG') = 0 then
f.Position:= 2
else
f.Position:= 0;
sz:= f.Size - f.Position;
FDiskImage.AllocateDiskSectors(f, rect, recs, recb);
Trace(etInfo, 'Allocated file VLIR record fork of size: ' +
IntToStr(sz) + ' (' + IntToStr(recb) + ' blocks)');
d^:= rect;
Inc(d);
d^:= recs;
Inc(d);
end;
end;
FDiskImage.AllocateDiskSectors(m, datt, dats, datb);
Trace(etInfo, 'Allocated file data fork of size: ' + IntToStr(m.Size) +
' (' + IntToStr(datb) + ' blocks)');
FDirEntry.SetDataTS(datt, dats);
FDirEntry.SetFileSize(datb);
finally
f.Free;
m.Free;
end;
end;
procedure TGEOSBuild.DoRun;
var
ErrorMsg: string;
p: string;
i: Integer;
o: Boolean;
begin
DoWriteBanner(True);
// quick check parameters
//dengland This doesn't check if the short and long versions have been specified
// at the same time, which I think it should. We will still get an error but
// its unintelligent.
ErrorMsg:= CheckOptions('hsv', ['help', 'silent', 'verbose']);
if ErrorMsg <> EmptyStr then
begin
//dengland This is probably a little extreme
// ShowException(Exception.Create(ErrorMsg));
Trace(etError, 'Error: ' + ErrorMsg);
ExitCode:= -2;
Terminate;
Exit;
end;
// parse parameters
if HasOption('h', 'help') then
begin
WriteHelp;
ExitCode:= -1;
Terminate;
Exit;
end;
//dengland Lets try to make sure only the short or long versions of the params
// are specified.
if ((FindOptionIndex('s', o) > -1)
and (FindOptionIndex('silent', o) > -1))
or ((FindOptionIndex('v', o) > -1)
and (FindOptionIndex('verbose', o) > -1)) then
begin
Trace(etError, 'Error: Only the short or long option versions should '+
'be specified.');
ExitCode:= -2;
Terminate;
Exit;
end;
i:= 0;
EventLogFilter:= [etDebug];
if HasOption('s', 'silent') then
begin
EventLogFilter:= EventLogFilter + [etInfo];
Inc(i);
end;
if HasOption('v', 'verbose') then
begin
EventLogFilter:= [];
Inc(i);
end;
try
if ParamCount = i then
raise EGEOSBuildError.Create(
'Error: A build file must be specified.');
if not FileExists(Params[i + 1]) then
raise EGEOSBuildError.Create('Error: Build file does not exist.');
p:= ExtractFilePath(Params[i + 1]);
if Length(p) > 0 then
begin
Trace(etInfo, 'Setting path to: ' + p);
SetCurrentDir(p);
end;
//dengland Must use ExtractFileName because we've changed the path if necessary.
DoProcessBuildFile(ExtractFileName(Params[i + 1]));
Trace(etCustom, 'Done.');
except
on E: EGEOSBuildError do
begin
Trace(etError, e.Message);
ExitCode:= -3;
end;
on E: Exception do
//dengland This won't go to ErrOutput which I'm unhappy about.
begin
ShowException(e);
ExitCode:= -4;
end;
end;
// stop program loop
Terminate;
end;
procedure TGEOSBuild.DoProcessBuildFile(const AFileName: string);
var
f: TIniFile;
s,
e: string;
b: Byte;
info: Integer;
inft: TD64TrackNum;
infs: TD64SectorNum;
infb: Word;
procedure DoOpenDiskImage;
var
d: TD64DiskType;
begin
s:= f.ReadString('build', 'Disk', '');
if Length(s) = 0 then
raise EGEOSBuildError.Create(
'Error: Disk Image FileName must be specified.');
FDiskImage:= TD64Image.Create;
if FileExists(s) then
begin
Trace(etInfo, 'Opening existing disk image: ' + s);
FDiskImage.LoadFromFile(s);
end
else
begin
Trace(etInfo, 'Creating new disk image: ' + s);
e:= ExtractFileExt(s);
if CompareText(e, '.D64') = 0 then
d:= ddt1541
else if CompareText(e, '.D71') = 0 then
d:= ddt1571
else if CompareText(e, '.D81') = 0 then
d:= ddt1581
else
raise EGEOSBuildError.Create(
'Error: Unknown Disk Image format specified.');
s:= ExtractFileName(s);
s:= Copy(s, 1, Length(s) - Length(e));
FDiskImage.FormatImage(s, '1a', d, True);
//dengland For testing purposes - to check new disk images
// FDiskImage.SaveToFile('test'+e);
end;
end;
procedure DoOpenInfoHeader;
begin
s:= f.ReadString('build', 'Header', '');
if not FileExists(s) then
raise EGEOSBuildError.Create(
'Error: Header/Info file does not exist or was not specified.');
FHeaderFile:= TMemoryStream.Create;
FHeaderFile.LoadFromFile(s);
//dengland We are supporting info/header blocks of 256 or 254 bytes in size.
// The info block is actually only 254 bytes but there must be some
// historical reason for geoLinker to require 256 bytes. If the size is
// 256, then the first two bytes are ignored (they will be "replaced" with
// the track and sector linkage information: $00, $FF).
info:= 0;
if FHeaderFile.Size = 256 then
info:= 2
else if FHeaderFile.Size <> 254 then
raise EGEOSBuildError.Create(
'Error: Header/Info size invalid. Must be 256 or 254 bytes.');
Trace(etInfo, 'Opened info/header file: ' + s);
Trace(etInfo, 'Info/header file size: ' + IntToStr(FHeaderFile.Size));
end;
procedure DoGetFileName;
var
i: Integer;
begin
FFileName:= f.ReadString('build', 'File', '');
if Length(FFileName) = 0 then
//dengland Try getting it from the header. This is important for applications
// on the C64 GEOS. C64 GEOS won't execute a file if the "permanent
// filename" (or class as I call it) is different from the directory
// entry filename.
begin
FHeaderFile.Position:= info + $4B;
s:= EmptyStr;
for i:= 0 to 11 do
begin
b:= FHeaderFile.ReadByte;
if b in [$20..$7E] then
s:= s + string(AnsiChar(b))
else
s:= s + ' ';
end;
FFileName:= TrimRight(s);
end;
if Length(FFileName) = 0 then
raise EGEOSBuildError.Create('Error: Output FileName must be specified.');
Trace(etInfo, 'Using destination file name: ' + FFileName);
end;
procedure DoAllocateInfoHeader;
begin
FHeaderFile.Position:= info;
FDiskImage.AllocateDiskSectors(FHeaderFile, inft, infs, infb);
Trace(etInfo, 'Allocated info/header sector.');
end;
procedure DoInitFileEntry;
var
e: TD64DirEntries;
i: Integer;
begin
FillChar(FDirEntry.EntryData[0], SizeOf(TD64EntryData), $00);
FDirEntry.SetFileName(FFileName);
FDirEntry.SetGEOSInfoTS(inft, infs); //SetRelTS
FHeaderFile.Position:= $42 + info;
FDirEntry.SetFileType(FHeaderFile.ReadByte);
FDirEntry.SetGEOSFileType(FHeaderFile.ReadByte);
b:= FHeaderFile.ReadByte;
FDirEntry.SetGEOSStructure(b);
// Check for an existing file entry with the same name. We don't want that.
FDiskImage.GetFileEntries(e);
for i:= 0 to High(e) do
if (e[i].FileType <> 0)
and (CompareText(TrimRight(e[i].FileName), FFileName) = 0) then
begin
Trace(etInfo, 'Scratching existing file.');
FDiskImage.ScratchFileEntry(e[i].Track, e[i].Sector,
e[i].EntryNum);
Break;
end;
end;
begin
Trace(etInfo, 'Processing: ' + AFileName);
f:= TIniFile.Create(AFileName);
try
DoOpenDiskImage;
DoOpenInfoHeader;
DoGetFileName;
DoAllocateInfoHeader;
DoInitFileEntry;
if b = $00 then
DoGEOSSequentialFile(f)
else
DoGEOSVLIRFile(f);
FDirEntry.SetGEOSDateTime(Now);
FDiskImage.AllocateFileEntry(FDirEntry.EntryData);
Trace(etInfo, 'Allocated file entry.');
FDiskImage.SaveToFile(f.ReadString('build', 'Disk', ''));
Trace(etInfo, 'Wrote disk image.');
finally
f.Free;
end;
end;
procedure TGEOSBuild.Trace(const AType: TEventType; const AMessage: string);
begin
if not (AType in EventLogFilter) then
if AType = etError then
Writeln(ErrOutput, AMessage)
else
Writeln(AMessage);
end;
constructor TGEOSBuild.Create(TheOwner: TComponent);
begin
inherited Create(TheOwner);
StopOnException:= True;
end;
destructor TGEOSBuild.Destroy;
begin
if Assigned(FHeaderFile) then
FreeAndNil(FHeaderFile);
if Assigned(FDiskImage) then
FreeAndNil(FDiskImage);
inherited Destroy;
end;
procedure TGEOSBuild.WriteHelp;
begin
DoWriteBanner(False);
Writeln('Usage: ', ExtractFileName(ExeName),
' [-h | --help] | [-s | --silent] <build file.gbuild>');
Writeln(EmptyStr);
Writeln(EmptyStr);
Writeln('GEOS Build links together the various files required for a GEOS' +
' application');
Writeln('or document into a D64/D71/D81 disk image in the correct format ' +
'for a GEOS file.');
Writeln(EmptyStr);
Writeln('A build file containing the instructions for building the file is'+
' required.');
Writeln(EmptyStr);
Writeln('The build file must contain information about the header (or' +
' info. block) in');
Writeln('order to build the file. It must also contain other information,'+
' depending');
Writeln('upon the file type detected in the header.');
Writeln(EmptyStr);
end;
var
Application: TGEOSBuild;
begin
Application:= TGEOSBuild.Create(nil);
Application.Title:= 'GEOS Build';
Application.Run;
Application.Free;
end.