forked from amix/photoshop
-
Notifications
You must be signed in to change notification settings - Fork 0
/
UDraw.a
1785 lines (1262 loc) · 27.3 KB
/
UDraw.a
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;Photoshop version 1.0.1, file: UDraw.a
; Computer History Museum, www.computerhistory.org
; This material is (C)Copyright 1990 Adobe Systems Inc.
; It may not be distributed to third parties.
; It is licensed for non-commercial use according to
; www.computerhistory.org/softwarelicense/photoshop/
INCLUDE 'Traps.a'
; **********************************************************************
SEG 'ADoDraw'
DoEraseRect PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoEraseRect (dataPtr: Ptr;
; dataWidth: INTEGER;
; rows: INTEGER;
; cols: INTEGER;
; color: INTEGER);
;
; Parameter Offsets
@dataPtr EQU 16
@dataWidth EQU 14
@rows EQU 12
@cols EQU 10
@color EQU 8
; Size of parameters
@params EQU 12
; Save registers
LINK A6,#0
MOVEM.L D3-D4,-(SP)
; Unload address
MOVE.L @dataPtr(A6),A0
; Unload background color
MOVE.W @color(A6),D2
; D3 is cols - 1
MOVE.W @cols(A6),D3
SUB.W #1,D3
; D4 is data width
MOVE.W @dataWidth(A6),D4
; Loop through rows and columns
MOVE.W @rows(A6),D0
SUB.W #1,D0
@1 MOVE.L A0,A1
MOVE.W D3,D1
; Copy value
@2 MOVE.B D2,(A1)+
; Move to next pixel
DBF D1,@2
ADDA.W D4,A0
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,D3-D4
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoDraw'
DoMagicRect PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoMagicRect (srcPtr: Ptr;
; dstPtr: Ptr;
; dataWidth: INTEGER;
; rows: INTEGER;
; cols: INTEGER);
;
; Parameter Offsets
@srcPtr EQU 18
@dstPtr EQU 14
@dataWidth EQU 12
@rows EQU 10
@cols EQU 8
; Size of parameters
@params EQU 14
; Save registers
LINK A6,#0
MOVEM.L A2-A3/D3,-(SP)
; Unload addresses
MOVE.L @srcPtr(A6),A0
MOVE.L @dstPtr(A6),A1
; D2 is data width
MOVE.W @dataWidth(A6),D2
; D3 is cols - 1
MOVE.W @cols(A6),D3
SUB.W #1,D3
; Loop through rows and columns
MOVE.W @rows(A6),D0
SUB.W #1,D0
@1 MOVE.L A0,A2
MOVE.L A1,A3
MOVE.W D3,D1
; Copy value
@2 MOVE.B (A2)+,(A3)+
; Move to next pixel
DBF D1,@2
ADDA.W D2,A0
ADDA.W D2,A1
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,A2-A3/D3
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoDraw'
DoAlphaEraseRect PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoAlphaEraseRect (dataPtr: Ptr;
; alphaPtr: Ptr;
; dataWidth: INTEGER;
; rows: INTEGER;
; cols: INTEGER;
; color: INTEGER);
;
; Parameter Offsets
@dataPtr EQU 20
@alphaPtr EQU 16
@dataWidth EQU 14
@rows EQU 12
@cols EQU 10
@color EQU 8
; Size of parameters
@params EQU 16
; Save registers
LINK A6,#0
MOVEM.L A2-A3/D3-D7,-(SP)
; Unload addresses
MOVE.L @dataPtr(A6),A0
MOVE.L @alphaPtr(A6),A1
; Unload background color
MOVE.W @color(A6),D2
; D3 is cols - 1
MOVE.W @cols(A6),D3
SUB.W #1,D3
; D4 is data width
MOVE.W @dataWidth(A6),D4
; Loop through rows and columns
MOVE.W @rows(A6),D0
SUB.W #1,D0
@1 MOVE.L A0,A2
MOVE.L A1,A3
MOVE.W D3,D1
; Get mask value
CLR.W D5
CLR.W D7
@2 MOVE.B (A3)+,D5
; If zero, leave value alone
BEQ.S @4
; If equal to 255, set to background color
CMP.B #255,D5
BEQ.S @3
; Compute weighted average
MOVE.W #256,D6
SUB.W D5,D6
MULU.W D2,D5
MOVE.B (A2),D7
MULU.W D7,D6
ADD.W D6,D5
ADD.W #128,D5
LSR.W #8,D5
MOVE.B D5,(A2)
BRA.S @4
; Set to background
@3 MOVE.B D2,(A2)
; Move to next pixel
@4 ADDA.W #1,A2
DBF D1,@2
ADDA.W D4,A0
ADDA.W D4,A1
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,A2-A3/D3-D7
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoDraw'
DoAlphaMagicRect PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoAlphaMagicRect (srcPtr: Ptr;
; dstPtr: Ptr;
; alphaPtr: Ptr;
; dataWidth: INTEGER;
; rows: INTEGER;
; cols: INTEGER);
;
; Parameter Offsets
@srcPtr EQU 22
@dstPtr EQU 18
@alphaPtr EQU 14
@dataWidth EQU 12
@rows EQU 10
@cols EQU 8
; Size of parameters
@params EQU 18
; Save registers
LINK A6,#0
MOVEM.L A2-A5/D3-D7,-(SP)
; Unload addresses
MOVE.L @srcPtr(A6),A0
MOVE.L @dstPtr(A6),A1
MOVE.L @alphaPtr(A6),A2
; D3 is cols - 1
MOVE.W @cols(A6),D3
SUB.W #1,D3
; D4 is data width
MOVE.W @dataWidth(A6),D4
; Loop through rows and columns
MOVE.W @rows(A6),D0
SUB.W #1,D0
@1 MOVE.L A0,A3
MOVE.L A1,A4
MOVE.L A2,A5
MOVE.W D3,D1
CLR.W D5
CLR.W D7
CLR.W D2
; Get buffer value
@2 MOVE.B (A3)+,D2
; Get mask value
MOVE.B (A5)+,D5
; If zero, leave value alone
BEQ.S @4
; If equal to 255, set to buffer
CMP.B #255,D5
BEQ.S @3
; Compute weighted average
MOVE.W #256,D6
SUB.W D5,D6
MULU.W D2,D5
MOVE.B (A4),D7
MULU.W D7,D6
ADD.W D6,D5
ADD.W #128,D5
LSR.W #8,D5
MOVE.B D5,(A4)
BRA.S @4
; Set to background
@3 MOVE.B D2,(A4)
; Move to next pixel
@4 ADDA.W #1,A4
DBF D1,@2
ADDA.W D4,A0
ADDA.W D4,A1
ADDA.W D4,A2
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,A2-A5/D3-D7
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoDraw'
DoAlphaMask PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoAlphaMask (maskPtr: Ptr;
; alphaPtr: Ptr;
; maskWidth: INTEGER;
; alphaWidth: INTEGER;
; rows: INTEGER;
; cols: INTEGER);
;
; Parameter Offsets
@maskPtr EQU 20
@alphaPtr EQU 16
@maskWidth EQU 14
@alphaWidth EQU 12
@rows EQU 10
@cols EQU 8
; Size of parameters
@params EQU 16
; Save registers
LINK A6,#0
MOVEM.L A2-A3/D3-D7,-(SP)
; Unload addresses
MOVE.L @maskPtr(A6),A0
MOVE.L @alphaPtr(A6),A1
; D3 is cols - 1
MOVE.W @cols(A6),D3
SUB.W #1,D3
; D4 is mask width
MOVE.W @maskWidth(A6),D4
; D7 is alpha width
MOVE.W @alphaWidth(A6),D7
; D5 is 255
MOVE.W #255,D5
; Loop through rows and columns
MOVE.W @rows(A6),D0
SUB.W #1,D0
@1 MOVE.L A0,A2
MOVE.L A1,A3
MOVE.W D3,D1
; Case 1: alpha = 0
@2 CLR.L D2
MOVE.B (A3)+,D2
BNE.S @3
CLR.B (A2)
BRA.S @5
; Case 2: alpha = 255
@3 CMP.W D5,D2
BEQ.S @5
; Case 3: 0 < alpha < 255 and mask = 0
CLR.L D6
MOVE.B (A2),D6
BEQ.S @5
; Case 4: 0 < alpha < 255 and mask = 255
CMP.W D5,D6
BNE.S @4
MOVE.B D2,(A2)
CLR.B -1(A3)
BRA.S @5
; Case 5: 0 < alpha < 255 and 0 < mask < 255
@4 MULU.W D2,D6
ADD.W #128,D6
LSR.W #8,D6
MOVE.B D6,(A2)
SUB.B D6,D2
NOT.B D6
ASL.W #8,D2
ADD.L D2,D2
ADD.L D6,D2
ADD.W D6,D6
DIVU.W D6,D2
BEQ.S @4A
SUB.W #1,D2
@4A MOVE.B D2,-1(A3)
; Move to next pixel
@5 ADDA.W #1,A2
DBF D1,@2
ADDA.W D4,A0
ADDA.W D7,A1
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,A2-A3/D3-D7
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoDraw'
DoFadeMask PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoFadeMask (srcPtr: Ptr;
; dstPtr: Ptr;
; count: INTEGER;
; drawings: INTEGER;
; fadeout: INTEGER);
;
; Parameter Offsets
@srcPtr EQU 18
@dstPtr EQU 14
@count EQU 12
@drawings EQU 10
@fadeout EQU 8
; Size of parameters
@params EQU 14
; Save registers
LINK A6,#0
; Unload addresses
MOVE.L @srcPtr(A6),A0
MOVE.L @dstPtr(A6),A1
; Compute scale factor
CLR.L D1
MOVE.W @drawings(A6),D1
SWAP D1
DIVU.W @fadeout(A6),D1
NOT.W D1
; Loop through data
MOVE.W @count(A6),D0
SUB.W #1,D0
@1 CLR.W D2
MOVE.B (A0)+,D2
MULU.W D1,D2
SWAP D2
MOVE.B D2,(A1)+
DBF D0,@1
; Clean up and exit
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoDraw'
DoThresholdMask PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoThresholdMask (srcPtr: Ptr;
; dstPtr: Ptr;
; count: INTEGER;
; pressure: INTEGER);
;
; Parameter Offsets
@srcPtr EQU 16
@dstPtr EQU 12
@count EQU 10
@pressure EQU 8
; Size of parameters
@params EQU 12
; Save registers
LINK A6,#0
; Unload addresses
MOVE.L @srcPtr(A6),A0
MOVE.L @dstPtr(A6),A1
; Loop through data
MOVE.W @count(A6),D0
SUB.W #1,D0
MOVE.W @pressure(A6),D1
NOT.B D1
@1 CMP.B (A0)+,D1
SLS (A1)+
DBF D0,@1
; Clean up and exit
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoDraw'
DoNarrowMask PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoNarrowMask (srcPtr: Ptr;
; dstPtr: Ptr;
; count: INTEGER;
; pressure: INTEGER);
;
; Parameter Offsets
@srcPtr EQU 16
@dstPtr EQU 12
@count EQU 10
@pressure EQU 8
; Size of parameters
@params EQU 12
; Save registers
LINK A6,#0
; Unload addresses
MOVE.L @srcPtr(A6),A0
MOVE.L @dstPtr(A6),A1
; Loop through data
MOVE.W @count(A6),D0
SUB.W #1,D0
MOVE.W @pressure(A6),D1
NOT.B D1
@1 MOVE.B (A0)+,D2
SUB.B D1,D2
BCC.S @2
CLR.B D2
@2 MOVE.B D2,(A1)+
DBF D0,@1
; Clean up and exit
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoDraw'
DoGetTip PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoGetTip (dataPtr: Ptr;
; buffPtr: Ptr;
; dataWidth: INTEGER;
; buffWidth: INTEGER;
; rows: INTEGER;
; cols: INTEGER);
;
; Parameter Offsets
@dataPtr EQU 20
@buffPtr EQU 16
@dataWidth EQU 14
@buffWidth EQU 12
@rows EQU 10
@cols EQU 8
; Size of parameters
@params EQU 16
; Save registers
LINK A6,#0
MOVEM.L A2-A3,-(SP)
; Unload addresses
MOVE.L @dataPtr(A6),A0
MOVE.L @buffPtr(A6),A1
; Loop through rows and columns
MOVE.W @rows(A6),D0
SUB.W #1,D0
SUB.W #1,@cols(A6)
@1 MOVE.L A0,A2
MOVE.L A1,A3
MOVE.W @cols(A6),D1
; Copy value
@2 MOVE.B (A2)+,(A3)+
; Move to next pixel
DBF D1,@2
ADDA.W @dataWidth(A6),A0
ADDA.W @buffWidth(A6),A1
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,A2-A3
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoDraw'
DoGetBlurred PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoGetBlurred (dataPtr: Ptr;
; buffPtr: Ptr;
; dataWidth: INTEGER;
; buffWidth: INTEGER;
; rows: INTEGER;
; cols: INTEGER);
;
; Parameter Offsets
@dataPtr EQU 20
@buffPtr EQU 16
@dataWidth EQU 14
@buffWidth EQU 12
@rows EQU 10
@cols EQU 8
; Size of parameters
@params EQU 16
; Save registers
LINK A6,#0
MOVEM.L A2-A3/D3-D5,-(SP)
; Unload addresses
MOVE.L @dataPtr(A6),A0
MOVE.L @buffPtr(A6),A1
; D2 and D3 are next and previous row offsets
MOVE.W @dataWidth(A6),D2
MOVE.W D2,D3
NEG.W D3
; D4 & D5 will hold byte values
CLR.W D4
CLR.W D5
; Loop through rows and columns
MOVE.W @rows(A6),D0
SUB.W #1,D0
SUB.W #1,@cols(A6)
@1 MOVE.L A0,A2
MOVE.L A1,A3
MOVE.W @cols(A6),D1
; Compute blurred value
@2 MOVE.B (A2)+,D4
ADD.W D4,D4
MOVE.B -2(A2),D5
ADD.W D5,D4
MOVE.B (A2),D5
ADD.W D5,D4
ADD.W D4,D4
MOVE.B -2(A2,D3.W),D5
ADD.W D5,D4
MOVE.B -1(A2,D3.W),D5
ADD.W D5,D4
ADD.W D5,D4
MOVE.B (A2,D3.W),D5
ADD.W D5,D4
MOVE.B -2(A2,D2.W),D5
ADD.W D5,D4
MOVE.B -1(A2,D2.W),D5
ADD.W D5,D4
ADD.W D5,D4
MOVE.B (A2,D2.W),D5
ADD.W D5,D4
ADD.W #8,D4
ASR.W #4,D4
MOVE.B D4,(A3)+
; Move to next pixel
@4 DBF D1,@2
ADDA.W D2,A0
ADDA.W @buffWidth(A6),A1
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,A2-A3/D3-D5
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoDraw'
DoGetSharpened PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoGetSharpened (dataPtr: Ptr;
; buffPtr: Ptr;
; dataWidth: INTEGER;
; buffWidth: INTEGER;
; rows: INTEGER;
; cols: INTEGER);
;
; Parameter Offsets
@dataPtr EQU 20
@buffPtr EQU 16
@dataWidth EQU 14
@buffWidth EQU 12
@rows EQU 10
@cols EQU 8
; Size of parameters
@params EQU 16
; Save registers
LINK A6,#0
MOVEM.L A2-A3/D3-D6,-(SP)
; Unload addresses
MOVE.L @dataPtr(A6),A0
MOVE.L @buffPtr(A6),A1
; D2 and D3 are next and previous row offsets
MOVE.W @dataWidth(A6),D2
MOVE.W D2,D3
NEG.W D3
; D6 contains the constant 255
MOVE.W #255,D6
; Loop through rows and columns
MOVE.W @rows(A6),D0
SUB.W #1,D0
SUB.W #1,@cols(A6)
@1 MOVE.L A0,A2
MOVE.L A1,A3
MOVE.W @cols(A6),D1
; Compute sharpened value
@2 CLR.W D4
MOVE.B (A2)+,D4
MULU.W #24,D4
CLR.W D5
MOVE.B -2(A2),D5
SUB.W D5,D4
MOVE.B (A2),D5
SUB.W D5,D4
MOVE.B -2(A2,D3.W),D5
SUB.W D5,D4
MOVE.B -1(A2,D3.W),D5
SUB.W D5,D4
MOVE.B (A2,D3.W),D5
SUB.W D5,D4
MOVE.B -2(A2,D2.W),D5
SUB.W D5,D4
MOVE.B -1(A2,D2.W),D5
SUB.W D5,D4
MOVE.B (A2,D2.W),D5
SUB.W D5,D4
ADD.W #7,D4
ASR.W #4,D4
BPL.S @3
CLR.W D4
@3 CMP.W D6,D4
BLE.S @3A
MOVE.W D6,D4
@3A MOVE.B D4,(A3)+
; Move to next pixel
@4 DBF D1,@2
ADDA.W D2,A0
ADDA.W @buffWidth(A6),A1
DBF D0,@1
; Clean up and exit
MOVEM.L (SP)+,A2-A3/D3-D6
UNLK A6
MOVE.L (SP)+,A0
ADD.W #@params,SP
JMP (A0)
; **********************************************************************
SEG 'ADoDraw'
DoMixBytes PROC EXPORT
; Calling sequence (Pascal conventions):
;
; PROCEDURE DoMixBytes (oldPtr: Ptr;
; newPtr: Ptr;
; mixMap: TLookUpTable;
; count: INTEGER);
;
; Parameter Offsets
@oldPtr EQU 18
@newPtr EQU 14
@mixMap EQU 10
@count EQU 8
; Size of parameters
@params EQU 14
; Save registers
LINK A6,#0
MOVE.L A2,-(SP)
; Unload addresses
MOVE.L @oldPtr(A6),A0
MOVE.L @newPtr(A6),A1
MOVE.L @mixMap(A6),A2
; Loop through bytes
MOVE.W @count(A6),D0
SUB.W #1,D0
CLR.W D1
CLR.W D2
@1 MOVE.B (A0),D1
MOVE.B (A1)+,D2