build.gradle

import java.text.SimpleDateFormat


plugins {
    id 'java'
    id 'groovy'
    id 'java-library'
    id 'maven-publish'
    id 'signing'
    id "io.github.gradle-nexus.publish-plugin" version "2.0.0"
    id "biz.aQute.bnd.builder" version "6.4.0"
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(11)
    }
}

def getDevelopmentVersion() {
    def output = new StringBuilder()
    def error = new StringBuilder()
    def gitShortHash = "git -C ${projectDir} rev-parse --short HEAD".execute()
    gitShortHash.waitForProcessOutput(output, error)
    def gitHash = output.toString().trim()
    if (gitHash.isEmpty()) {
        println "git hash is empty: error: ${error.toString()}"
        throw new IllegalStateException("git hash could not be determined")
    }
    "0.0.0-" + new SimpleDateFormat('yyyy-MM-dd\'T\'HH-mm-ss').format(new Date()) + "-" + gitHash
}

def releaseVersion = System.env.RELEASE_VERSION
version = releaseVersion ? releaseVersion : getDevelopmentVersion()
println "Building version = " + version
group = 'com.graphql-java'

repositories {
    mavenCentral()
    mavenLocal()
}

dependencies {
    implementation "com.graphql-java:graphql-java:22.1"

    testImplementation "org.spockframework:spock-core:2.3-groovy-3.0"
    testImplementation "org.codehaus.groovy:groovy:3.0.22"
}

task sourcesJar(type: Jar, dependsOn: classes) {
    archiveClassifier.set("sources")
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    archiveClassifier.set("javadoc")
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

test {
    useJUnitPlatform()
    testLogging {
        exceptionFormat = 'full'
    }
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java
            groupId group
            artifactId 'graphql-java-extended-scalars'
            version version

            artifact sourcesJar
            artifact javadocJar

            pom.withXml {
                asNode().children().last() + {
                    resolveStrategy = Closure.DELEGATE_FIRST
                    name 'graphql-java-extended-scalars'
                    description 'A library of extended scalars for graphql-java'
                    url 'https://github.com/graphql-java/graphql-java-extended-scalars'
                    inceptionYear '2018'

                    scm {
                        url 'https://github.com/graphql-java/graphql-java-extended-scalars'
                        connection 'scm:git@github.com:graphql-java/graphql-java-extended-scalars.git'
                        developerConnection 'scm:git@github.com:graphql-java/graphql-java-extended-scalars.git'
                    }

                    licenses {
                        license {
                            name 'MIT'
                            url 'https://github.com/graphql-java/graphql-java/blob/master/LICENSE.md'
                            distribution 'repo'
                        }
                    }

                    developers {
                        developer {
                            id 'bbakerman'
                            name 'Brad Baker'
                            email 'bbakerman@gmail.com'
                        }
                    }
                }
            }
        }
    }
}

nexusPublishing {
    repositories {
        sonatype {
            username = System.env.MAVEN_CENTRAL_USER
            password = System.env.MAVEN_CENTRAL_PASSWORD
        }
    }
}

signing {
    def signingKey = System.env.MAVEN_CENTRAL_PGP_KEY
    useInMemoryPgpKeys(signingKey, "")
    sign publishing.publications
}

// all publish tasks depend on the build task
tasks.withType(PublishToMavenRepository) {
    dependsOn build
}

jar {
    manifest {
        attributes('Automatic-Module-Name': 'com.graphqljava.extendedscalars',
                '-exportcontents': 'graphql.scalars.*',
                '-removeheaders': 'Private-Package')
    }
}