-
Notifications
You must be signed in to change notification settings - Fork 0
/
struct.ijs
1469 lines (1385 loc) · 48.3 KB
/
struct.ijs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
NB. Structure handlers
NB.
NB. c Columns in noun
NB. trace Matrix trace
NB. ct Conjugate transpose
NB. cp Conjugate pertranspose
NB. fp Full (symmetric) permutation
NB. P4p Transform permutation vector to/from
NB. permutation matrix
NB. P4ip Transform inversed permutation vector to/from
NB. permutation matrix
NB. rt Restrained Take
NB. icut Inversed cut
NB.
NB. e0 Extend matrix by zeros
NB. appendx Enhance built-in Append verb (,)
NB. stitchx Enhance built-in Stitch verb (,.)
NB. ds Direct sum of matrices A⊕B
NB.
NB. diag Return a solid part of diagonal
NB. setdiag Assign value(s) to a solid part of diagonal
NB. upddiag Adv. to make verbs to update a solid part of
NB. diagonal
NB.
NB. bdlpick Zeroize elements outside lower bidiagonal part
NB. of the matrix
NB. bdupick Zeroize elements outside upper bidiagonal part
NB. of the matrix
NB. hslpick Zeroize elements outside lower Hessenberg part
NB. of the matrix
NB. hsupick Zeroize elements outside upper Hessenberg part
NB. of the matrix
NB. gtpick Zeroize elements outside tridiagonal part of
NB. the matrix
NB. trlpick Zeroize elements outside lower trapezoidal part
NB. of the matrix
NB. trupick Zeroize elements outside upper trapezoidal part
NB. of the matrix
NB. trl1pick Zeroize elements outside lower trapezoidal part
NB. of the matrix and set diagonal to 1
NB. tru1pick Zeroize elements outside upper trapezoidal part
NB. of the matrix and set diagonal to 1
NB.
NB. idmat Make identity matrix with units on solid part
NB. of diagonal
NB. diagmat Make diagonal matrix
NB. trl Extract lower trapezoidal matrix
NB. tru Extract upper trapezoidal matrix
NB. trl0 Extract strictly lower trapezoidal matrix
NB. tru0 Extract strictly upper trapezoidal matrix
NB. trl1 Extract unit lower trapezoidal matrix
NB. tru1 Extract unit upper trapezoidal matrix
NB. xx4gex Compose structured matrix from SLT (SUT) part
NB. and diagonal of square matrix
NB. xxxxxy Compose matrix from triangular parts of general
NB. matrices
NB. sxxsxy Adv. to make dyad to compose matrix from strict
NB. triangular parts of general matrices
NB. po Make Hermitian (symmetric) positive definite
NB. matrix from square invertible one
NB.
NB. Copyright 2005 Roger Hui (icut verb)
NB. Copyright 2010,2011,2013,2017,2018,2020,2021,2023,2024
NB. Igor Zhuravlov
NB.
NB. This file is part of mt
NB.
NB. mt is free software: you can redistribute it and/or
NB. modify it under the terms of the GNU Lesser General
NB. Public License as published by the Free Software
NB. Foundation, either version 3 of the License, or (at your
NB. option) any later version.
NB.
NB. mt is distributed in the hope that it will be useful, but
NB. WITHOUT ANY WARRANTY; without even the implied warranty
NB. of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
NB. See the GNU Lesser General Public License for more
NB. details.
NB.
NB. You should have received a copy of the GNU Lesser General
NB. Public License along with mt. If not, see
NB. <http://www.gnu.org/licenses/>.
NB. =========================================================
NB. Concepts
NB.
NB. Notation:
NB. array ranks:
NB. l-vector - a vector of length l e.g. "2-vector v"
NB. s-matrix - a matrix of shape s e.g. "2×3-matrix M"
NB. s-brick - a brick of shape s e.g. "2×3×4-brick B"
NB. r-rank - an array of rank r e.g. "3-rank array A"
NB. matrix types:
NB. BD,BDL,BDU - [{lower,upper}] bidiagonal
NB. DI - diagonalizable
NB. GE - general
NB. GG - general-general pair, generalized form
NB. GT - general tridiagonal
NB. HE - Hermitian for complex data type
NB. (symmetric for float data type)
NB. HG - Hessenberg-triangular pair, generalized
NB. Hessenberg form
NB. HS,HSL,HSU - [{lower,upper}] Hessenberg
NB. HT - Hermitian (symmetric) tridiagonal
NB. OR - orthogonal
NB. PO - Hermitian (symmetric) positive definite
NB. PT - Hermitian (symmetric) positive definite
NB. tridiagonal
NB. SY - symmetric
NB. TG - triangular-triangular pair, generalized
NB. Schur form
NB. TR - triangular
NB. TZ - trapezoidal
NB. UN - unitary for complex data type
NB. (orthogonal for float data type)
NB. triangular matrix [parts]:
NB. L - lower triangular matrix
NB. L1 - unit lower triangular matrix
NB. U - upper triangular matrix
NB. U1 - unit upper triangular matrix
NB. LT - lower triangular part of matrix
NB. SLT - strict lower triangular part of matrix
NB. UT - upper triangular part of matrix
NB. SUT - strict upper triangular part of matrix
NB.
NB. Notes:
NB. - unit diagonal in L1 and U1 is usually neither stored
NB. nor referenced
NB. =========================================================
NB. Configuration
coclass 'mt'
NB. =========================================================
NB. Local definitions
NB. ---------------------------------------------------------
NB. ft4lisoa
NB.
NB. Description:
NB. Functional table for linear ISO, all axes
NB.
NB. Syntax:
NB. ft=. (op ft4lisoa) a
NB. where
NB. op - dyad to compute a value from axes IO
NB. a - m×n-matrix
NB. ft - the same shape as a, functional table:
NB. ft -: m op/&i. n
NB.
NB. Examples:
NB. < ft4lisoa 3 4 $ 0 > ft4lisoa 3 4 $ 0
NB. 0 1 1 1 0 0 0 0
NB. 0 0 1 1 1 0 0 0
NB. 0 0 0 1 1 1 0 0
NB.
NB. <: ft4lisoa 3 4 $ 0 >: ft4lisoa 3 4 $ 0
NB. 1 1 1 1 1 0 0 0
NB. 0 1 1 1 1 1 0 0
NB. 0 0 1 1 1 1 1 0
NB.
NB. - ft4lisoa 3 4 $ 0 -~ ft4lisoa 3 4 $ 0
NB. 0 _1 _2 _3 0 1 2 3
NB. 1 0 _1 _2 _1 0 1 2
NB. 2 1 0 _1 _2 _1 0 1
NB.
NB. + ft4lisoa 3 4 $ 0
NB. 0 1 2 3
NB. 1 2 3 4
NB. 2 3 4 5
ft4lisoa=: /(&i.)/(@$)
NB. ---------------------------------------------------------
NB. Miscellaneous
NB. conj. to extract matrix circumscribing the trapezoidal
NB. matrix starting from diagonal number x in the matrix y
trcut=: 2 : '(u@(0 >. <./"1)@v $) {. ]'
NB. extract upper trapezoidal matrix
trucut=: ]`-"0 trcut (] ,. (-~ {:))
NB. extract lower trapezoidal matrix
trlcut=: -`]"0 trcut ((+ {.) ,. ])
NB. conj. to extract trapezoidal matrix starting from
NB. diagonal number x in the circumscribing matrix y
tr=: 2 : '0&$: :([ ((u~ (-~ ft4lisoa)) {.`(0 ,: {:)}@,: ]) v)'
NB. ---------------------------------------------------------
NB. mxbstencil
NB.
NB. Description:
NB. Adv. to make dyad returning [multi-][anti-]band
NB. stencil for matrix
NB.
NB. Syntax:
NB. S=. bs (vmix mxbstencil) A
NB. where
NB. vmix - dyad to mix lISO x and y, is either (-~) for
NB. band, or (+) for anti-band stencils, is called
NB. as:
NB. mix=. lIOrow vmix lIOcolumn
NB. bs - k×2-matrix of (b)s, or single b, or d, defines
NB. [anti-]bands to stencil
NB. b - 2-vector (h,t), defines one [anti-]band to
NB. stencil
NB. h - integer in range [-∞,t], lIO head of
NB. [anti-]diagonal
NB. t - integer in range [h,+∞], lIO tail of
NB. [anti-]diagonal
NB. d - integer in range [-∞,+∞], lIO single
NB. [anti-]diagonal to stencil
NB. A - m×n-matrix
NB. S - m×n-matrix, boolean, having 1s on [anti-]band(s)
NB.
NB. Examples:
NB. - see mbstencil, mabstencil
mxbstencil=: 1 : '(+./^:(_2 + #@$)@:((1=I.)"1 2)~ -&1 0"1)~ (u ft4lisoa)'
NB. ---------------------------------------------------------
NB. mbstencil
NB. mabstencil
NB.
NB. Description:
NB. [Multi-]band and [multi-]anti-band stencils for matrix
NB.
NB. Syntax:
NB. S=. bs mbstencil A
NB. S=. bs mabstencil A
NB. where
NB. bs - k×2-matrix of (b)s, or single b, or d, defines
NB. [anti-]bands to stencil
NB. A - m×n-matrix
NB. S - m×n-matrix, boolean, having 1s on [anti-]band(s)
NB. b - 2-vector (h,t), defines one [anti-]band to stencil
NB. h - integer in range [-∞,t], defines lIO head of
NB. [anti-]diagonal
NB. t - integer in range [h,+∞], defines lIO tail of
NB. [anti-]diagonal
NB. d - integer in range [-∞,+∞], defines one
NB. [anti-]diagonal to stencil
NB.
NB. Examples:
NB. 1 mbstencil i. 3 5 1 mabstencil i. 3 5
NB. 0 1 0 0 0 0 0 0 1 0
NB. 0 0 1 0 0 0 0 1 0 0
NB. 0 0 0 1 0 0 1 0 0 0
NB.
NB. 2 3 mbstencil i. 3 5 2 3 mabstencil i. 3 5
NB. 0 0 1 1 0 0 1 1 0 0
NB. 0 0 0 1 1 1 1 0 0 0
NB. 0 0 0 0 1 1 0 0 0 0
NB.
NB. (__ _1 ,: 2 3) mbstencil i. 3 5 (__ _1 ,: 2 3) mabstencil i. 3 5
NB. 0 0 1 1 0 0 1 1 0 0
NB. 1 0 0 1 1 1 1 0 0 1
NB. 1 1 0 0 1 1 0 0 1 1
mbstencil=: -~ mxbstencil
mabstencil=: (|."1@:-~ <:@c) (+ mxbstencil) ]
NB. ---------------------------------------------------------
NB. diagliso
NB.
NB. Description:
NB. Return lISO solid part of diagonal of matrix
NB.
NB. Syntax:
NB. liso=. [(d[,h[,s]])] diagliso [m,]n
NB. where
NB. m ≥ 0, integer, optional rows in matrix, default is
NB. n
NB. n ≥ 0, integer, columns in matrix
NB. d - integer in range [1-m,n-1], optional lIO
NB. diagonal, default is 0 (main diagonal)
NB. h - integer in range [-S,S-1], optional lIO extreme
NB. element of solid part of diagonal, default is 0
NB. (take from head)
NB. s - integer in range [-S,S] or ±∞, optional size of
NB. solid part of diagonal, default is +∞ (all
NB. elements in forward direction)
NB. liso - min(S,|s|)-vector of integers, lISO solid
NB. part of diagonal
NB. S ≥ 0, the length of diagonal
NB.
NB. Formula:
NB. - the whole diagonal's lIO extreme element:
NB. H := (d ≥ 0) ? d : (-n*d)
NB. - the whole diagonal's size:
NB. S := max(0,min(m,n,⌊(n+m-|n-m-2*d|)/2⌋))
NB.
NB. Notes:
NB. - (h,s) pair defines raveled rISO solid part of
NB. diagonal
diagliso=: 0 0 _&$: :(4 : 0)
'd h s'=. x=. ((i. 3) < (# x))} 0 0 _ ,: x
'm n'=. y=. 2 $ y
H=. n (-@*^:(0 > ])) d
S=. 0 >. <./ y , <. -: (n + m - | n - m + +: d)
(h ,: s <. S) (];.0) (>: n) liso4dhs H , S
)
NB. =========================================================
NB. Interface
NB. ---------------------------------------------------------
NB. Miscellaneous
c=: {:!.1@$ NB. Columns in noun
trace=: +/!.0@diag NB. Matrix trace
ct=: +@:|: NB. Conjugate transpose
cp=: ct&.|. NB. Conjugate pertranspose
NB. Do/undo full (symmetric) permutation
NB. Syntax:
NB. Aperm=. p fp A
NB. A=. p fp^:_1 Aperm
fp=: ([ C."1 C.) :. ([ C.^:_1"1 C.^:_1)
NB. Transform permutation vector to/from permutation matrix,
NB. to permute rows by y or columns by (/: y)
P4p=: (C. =) :. ( i.&1"1 )
NB. Transform inversed permutation vector to/from permutation
NB. matrix, or permutation vector to/from inversed
NB. permutation matrix, to permute rows by (/: y) or columns
NB. by y
P4ip=: (C.^:_1 =) :. (/:@:(i.&1"1))
NB. ---------------------------------------------------------
NB. icut
NB.
NB. Description:
NB. Inversed cut to model <;.1^:_1
NB.
NB. Syntax:
NB. A=. icut bA
NB. where
NB. bA - block array
NB. A - sh-array
NB.
NB. Assertions:
NB. A -: icut fret <;.1 A
NB. where
NB. A - some array
NB. fret - some fret
NB.
NB. TODO:
NB. - fret would be sparse
NB.
NB. References:
NB. [1] Roger Hui. JWiki/Essays/Block Matrix Inverse.
NB. 2005-11-24 03:53:19.
NB. http://code.jsoftware.com/wiki/Essays/Block%20Matrix%20Inverse
icut=: [: > 3 : ',"(#$y)&.>/y'^:(#@$)
NB. ---------------------------------------------------------
NB. rt
NB.
NB. Description:
NB. Restrained Take. Just like built-in Take verb ({.), but
NB. without overtake feature. Overtaking value means "all
NB. elements along this axis".
NB.
NB. Examples:
NB. 2 rt i. 3 4 _2 rt i. 3 4
NB. 0 1 2 3 4 5 6 7
NB. 4 5 6 7 8 9 10 11
NB.
NB. 2 30 rt i. 3 4 2 _ rt i. 3 4
NB. 0 1 2 3 0 1 2 3
NB. 4 5 6 7 4 5 6 7
NB.
NB. 20 3 rt i. 3 4 _ 3 rt i. 3 4
NB. 0 1 2 0 1 2
NB. 4 5 6 4 5 6
NB. 8 9 10 8 9 10
NB.
NB. _2 _30 rt i. 3 4 _2 __ rt i. 3 4
NB. 4 5 6 7 4 5 6 7
NB. 8 9 10 11 8 9 10 11
NB.
NB. _20 _3 rt i. 3 4 __ _3 rt i. 3 4
NB. 1 2 3 1 2 3
NB. 5 6 7 5 6 7
NB. 9 10 11 9 10 11
rt=: (*@[ * |@[ <. (({.~ #)~ $)) {. ]
NB. ---------------------------------------------------------
NB. e0
NB.
NB. Description:
NB. Extend matrix by blanks
NB.
NB. Syntax:
NB. eA=. sh e0 A
NB. where
NB. A - matrix to extend
NB. sh - scalar or 2-vector, integer, extended size
NB. eA - extend A
NB.
NB. Examples:
NB. 2 e0 3 4 $ 1 2 3 e0 3 4 $ 1 2 _3 e0 3 4 $ 1
NB. 1 1 1 1 0 0 1 1 1 1 0 0 0 0 0 0 1 1 1 1
NB. 1 1 1 1 0 0 1 1 1 1 0 0 0 0 0 0 1 1 1 1
NB. 1 1 1 1 0 0 1 1 1 1 0 0 0 0 0 0 1 1 1 1
NB. 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
NB. 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
NB.
NB. _2 e0 3 4 $ 1 _2 3 e0 3 4 $ 1 _2 _3 e0 3 4 $ 1
NB. 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
NB. 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
NB. 0 0 1 1 1 1 1 1 1 1 0 0 0 0 0 0 1 1 1 1
NB. 0 0 1 1 1 1 1 1 1 1 0 0 0 0 0 0 1 1 1 1
NB. 0 0 1 1 1 1 1 1 1 1 0 0 0 0 0 0 1 1 1 1
NB.
NB. ((stitcht ' '&,.)&(":@<) _1 _2&e0) 3 4 $ 'abcdefghijkl'
NB. +----+ +------+
NB. |abcd| | |
NB. |efgh| | abcd|
NB. |ijkl| | efgh|
NB. +----+ | ijkl|
NB. +------+
e0=: ([ + (negneg"0 $)) {. ]
NB. ---------------------------------------------------------
NB. appendl
NB. appendr
NB.
NB. Description:
NB. Enhance built-in Append verb (,)
NB.
NB. Syntax:
NB. B=. A0 appendx A1
NB.
NB. Examples:
NB. (3 3$3) appendl (2 2$2) (3 3$3) appendr (2 2$2)
NB. 3 3 3 3 3 3
NB. 3 3 3 3 3 3
NB. 3 3 3 3 3 3
NB. 2 2 0 0 2 2
NB. 2 2 0 0 2 2
NB.
NB. (2 2$2) appendl (3 3$3) (2 2$2) appendr (3 3$3)
NB. 2 2 0 0 2 2
NB. 2 2 0 0 2 2
NB. 3 3 3 3 3 3
NB. 3 3 3 3 3 3
NB. 3 3 3 3 3 3
NB.
NB. Notes:
NB. - at most one of A0, A1 can be 1-rank array (i.e. vector)
appendl=: , `([, ({."1~ c)~)`(({."1~ c), ])@.(*@-&c)
appendr=: , `([, ({."1~ -@c)~)`(({."1~ -@c), ])@.(*@-&c)
NB. ---------------------------------------------------------
NB. stitcht
NB. stitchb
NB.
NB. Description:
NB. Enhance built-in Stitch verb (,.)
NB.
NB. Syntax:
NB. B=. A0 stitchx A1
NB.
NB. Examples:
NB. (3 3$3) stitcht (2 2$2) (3 3$3) stitchb (2 2$2)
NB. 3 3 3 2 2 3 3 3 0 0
NB. 3 3 3 2 2 3 3 3 2 2
NB. 3 3 3 0 0 3 3 3 2 2
NB.
NB. (2 2$2) stitcht (3 3$3) (2 2$2) stitchb (3 3$3)
NB. 2 2 3 3 3 0 0 3 3 3
NB. 2 2 3 3 3 2 2 3 3 3
NB. 0 0 3 3 3 2 2 3 3 3
NB.
NB. Notes:
NB. - 1-rank arrays (i.e. vectors) are also acceptable
stitcht=: ,.`([,.({. ~ #)~)`(({. ~ #),.])@.(*@-&#)
stitchb=: ,.`([,.({. ~ -@#)~)`(({. ~ -@#),.])@.(*@-&#)
NB. ---------------------------------------------------------
NB. ds
NB.
NB. Description:
NB. Direct sum of matrices A⊕B
NB.
NB. Syntax:
NB. C=. A ds B
NB. where
NB. A - ma×na-matrix
NB. B - mb×nb-matrix
NB. C - (ma+mb)×(na+nb)-matrix:
NB. C = ( A 0 )
NB. ( 0 B )
ds=: (+&c {."1 [) appendr ]
NB. ---------------------------------------------------------
NB. diag
NB.
NB. Description:
NB. Return a solid part of diagonal of matrix
NB.
NB. Syntax:
NB. e=. [(d[,h[,s]])] diag A
NB. where
NB. A - m×n-matrix
NB. d - integer in range [1-m,n-1], optional lIO diagonal,
NB. default is 0 (main diagonal)
NB. h - integer in range [-S,S-1], optional lIO extreme
NB. element of solid part of diagonal, default is 0
NB. (take from head)
NB. s - integer in range [-S,S] or ±∞, optional size of
NB. solid part of diagonal, default is +∞ (all elements
NB. in forward direction)
NB. e - min(S,|s|)-vector, elements from the solid part of
NB. diagonal
NB. S ≥ 0, the length of diagonal
diag=: ((<0 1)&|:) :((diagliso $) ({,) ])
NB. ---------------------------------------------------------
NB. setdiag
NB.
NB. Description:
NB. Assign value(s) to a solid part of diagonal
NB.
NB. Syntax:
NB. Aupd=. (e;[d[,h[,s]]]) setdiag A
NB. where
NB. A - m×n-matrix to change
NB. e - {0,1}-rank array, value(s) to assign
NB. d - integer in range [1-m,n-1], optional lIO
NB. diagonal, default is 0 (main diagonal)
NB. h - integer in range [-S,S-1], optional lIO extreme
NB. element of solid part of diagonal, default is 0
NB. (take from head)
NB. s - integer in range [-S,S] or ±∞ when e is scalar,
NB. or any from set {±k,±∞} when e is vector;
NB. optional size of solid part of diagonal, default
NB. is +∞ (all elements in forward direction)
NB. Aupd - m×n-matrix A with value(s) e assigned to solid
NB. part of d-th diagonal
NB. S ≥ 0, the length of d-th diagonal
NB. k ≤ S, the length of vector e
NB.
NB. Examples:
NB. (2;a:) setdiag 4 4 $ 0 (2;_1 1 1) setdiag 4 4 $ 0
NB. 2 0 0 0 0 0 0 0
NB. 0 2 0 0 0 0 0 0
NB. 0 0 2 0 0 2 0 0
NB. 0 0 0 2 0 0 0 0
NB.
NB. (2;_1) setdiag 4 4 $ 0 (1 2 3;_1) setdiag 4 4 $ 0
NB. 0 0 0 0 0 0 0 0
NB. 2 0 0 0 1 0 0 0
NB. 0 2 0 0 0 2 0 0
NB. 0 0 2 0 0 0 3 0
NB.
NB. (2;_1 1) setdiag 4 4 $ 0 (1 2 3;_1 _1 _3) setdiag 4 4 $ 0
NB. 0 0 0 0 0 0 0 0
NB. 0 0 0 0 3 0 0 0
NB. 0 2 0 0 0 2 0 0
NB. 0 0 2 0 0 0 1 0
setdiag=: 4 : 0
'e dhs'=. x
dhs=. ((i. 3) < (# dhs))} 0 0 _ ,: dhs NB. assign defaults, in-place op
liso=. dhs diagliso $ y
e (liso"_)} y
)
NB. ---------------------------------------------------------
NB. upddiag
NB.
NB. Description:
NB. Adv. to make verbs to update a solid part of diagonal
NB.
NB. Syntax:
NB. Aupd=. [(d,[h[,s]])] (u upddiag) A
NB. where
NB. u - monad to change elements; is called as:
NB. eupd=. u e
NB. d - integer in range [1-m,n-1], optional lIO
NB. diagonal, default is 0 (main diagonal)
NB. h - integer in range [-S,S-1], optional lIO extreme
NB. element of solid part of diagonal, default is 0
NB. (take from head)
NB. s - integer in range [-S,S] or ±∞, optional size of
NB. solid part of diagonal, default is +∞ (all
NB. elements in forward direction)
NB. A - m×n-matrix to update
NB. Aupd - A with solid part of d-th diagonal updated by
NB. monad u
NB. S ≥ 0, the length of d-th diagonal
NB.
NB. Examples:
NB. +&0j1 upddiag i. 5 5 0 +&0j1 upddiag i. 5 5
NB. 0j1 1 2 3 4 0j1 1 2 3 4
NB. 5 6j1 7 8 9 5 6j1 7 8 9
NB. 10 11 12j1 13 14 10 11 12j1 13 14
NB. 15 16 17 18j1 19 15 16 17 18j1 19
NB. 20 21 22 23 24j1 20 21 22 23 24j1
NB.
NB. 0 1 +&0j1 upddiag i. 5 5 0 1 3 +&0j1 upddiag i. 5 5
NB. 0 1 2 3 4 0 1 2 3 4
NB. 5 6j1 7 8 9 5 6j1 7 8 9
NB. 10 11 12j1 13 14 10 11 12j1 13 14
NB. 15 16 17 18j1 19 15 16 17 18j1 19
NB. 20 21 22 23 24j1 20 21 22 23 24
NB.
NB. 1 +&0j1 upddiag i. 5 5 _1 +&0j1 upddiag i. 5 5
NB. 0 1j1 2 3 4 0 1 2 3 4
NB. 5 6 7j1 8 9 5j1 6 7 8 9
NB. 10 11 12 13j1 14 10 11j1 12 13 14
NB. 15 16 17 18 19j1 15 16 17j1 18 19
NB. 20 21 22 23 24 20 21 22 23j1 24
upddiag=: 1 : 'diagliso_mt_^:(1:`(] $)) (u {{(u x ({,) y) (x"_)} y}}) ]'
NB. ---------------------------------------------------------
NB. bdlpick
NB.
NB. Description:
NB. Zeroize elements outside lower bidiagonal part of the
NB. matrix
NB.
NB. Syntax:
NB. B=. bdlpick A
NB. where
NB. A - m×n-matrix, contains B
NB. B - m×n-matrix, the lower bidiagonal
NB.
NB. Examples:
NB. bdlpick 4 5 $ 1 bdlpick 5 4 $ 1 bdlpick 5 5 $ 1
NB. 1 0 0 0 0 1 0 0 0 1 0 0 0 0
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 0 1 1 0 0 0 1 1 0 0 1 1 0 0
NB. 0 0 1 1 0 0 0 1 1 0 0 1 1 0
NB.
NB. TODO:
NB. - B would be sparse
bdlpick=: _1 0&mbstencil`(0&,:)}
NB. ---------------------------------------------------------
NB. bdupick
NB.
NB. Description:
NB. Zeroize elements outside upper bidiagonal part of the
NB. matrix
NB.
NB. Syntax:
NB. B=. bdupick A
NB. where
NB. A - m×n-matrix, contains B
NB. B - m×n-matrix, the upper bidiagonal
NB.
NB. Examples:
NB. bdupick 4 5 $ 1 bdupick 5 4 $ 1 bdupick 5 5 $ 1
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 0 1 1 0 0 0 1 1 0 0 1 1 0 0
NB. 0 0 1 1 0 0 0 1 1 0 0 1 1 0
NB. 0 0 0 1 1 0 0 0 1 0 0 0 1 1
NB. 0 0 0 0 0 0 0 0 1
NB.
NB. TODO:
NB. - B would be sparse
bdupick=: 0 1&mbstencil`(0&,:)}
NB. ---------------------------------------------------------
NB. hslpick
NB.
NB. Description:
NB. Zeroize elements outside lower Hessenberg part of the
NB. matrix
NB.
NB. Syntax:
NB. B=. hslpick A
NB. where
NB. A - m×n-matrix, contains B
NB. B - m×n-matrix, the lower Hessenberg
NB.
NB. Examples:
NB. hslpick 4 5 $ 1 hslpick 5 4 $ 1 hslpick 5 5 $ 1
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 1 1 1 0 0 1 1 1 0 1 1 1 0 0
NB. 1 1 1 1 0 1 1 1 1 1 1 1 1 0
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 1 1 1 1 1 1 1 1 1
hslpick=: __ 1&mbstencil`(0&,:)}
NB. ---------------------------------------------------------
NB. hsupick
NB.
NB. Description:
NB. Zeroize elements outside upper Hessenberg part of the
NB. matrix
NB.
NB. Syntax:
NB. B=. hsupick A
NB. where
NB. A - m×n-matrix, contains B
NB. B - m×n-matrix, the upper Hessenberg
NB.
NB. Examples:
NB. hsupick 4 5 $ 1 hsupick 5 4 $ 1 hsupick 5 5 $ 1
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 0 1 1 1 1 0 1 1 1 0 1 1 1 1
NB. 0 0 1 1 1 0 0 1 1 0 0 1 1 1
NB. 0 0 0 1 0 0 0 1 1
hsupick=: _1 _&mbstencil`(0&,:)}
NB. ---------------------------------------------------------
NB. gtpick
NB.
NB. Description:
NB. Zeroize elements outside tridiagonal part of the matrix
NB.
NB. Syntax:
NB. B=. gtpick A
NB. where
NB. A - m×n-matrix, contains B
NB. B - m×n-matrix, tridiagonal
NB.
NB. Examples:
NB. gtpick 4 5 $ 1 gtpick 5 4 $ 1 gtpick 5 5 $ 1
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 1 1 1 0 0 1 1 1 0 1 1 1 0 0
NB. 0 1 1 1 0 0 1 1 1 0 1 1 1 0
NB. 0 0 1 1 1 0 0 1 1 0 0 1 1 1
NB. 0 0 0 1 0 0 0 1 1
NB.
NB. TODO:
NB. - B would be sparse
gtpick=: _1 1&mbstencil`(0&,:)}
NB. ---------------------------------------------------------
NB. trlpick
NB.
NB. Description:
NB. Zeroize elements outside lower trapezoidal part of the
NB. matrix
NB.
NB. Syntax:
NB. B=. [d] trlpick A
NB. where
NB. A - m×n-matrix, contains B
NB. d - integer in range [-∞,+∞], optional lIO last
NB. non-zero diagonal, default is 0
NB. B - m×n-matrix, the lower trapezoidal
NB.
NB. Examples:
NB. trlpick 4 5 $ 1 trlpick 5 4 $ 1 trlpick 5 5 $ 1
NB. 1 0 0 0 0 1 0 0 0 1 0 0 0 0
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 1 1 1 0 0 1 1 1 0 1 1 1 0 0
NB. 1 1 1 1 0 1 1 1 1 1 1 1 1 0
NB. 1 1 1 1 1 1 1 1 1
NB.
NB. 0 trlpick 4 5 $ 1 0 trlpick 5 4 $ 1 0 trlpick 5 5 $ 1
NB. 1 0 0 0 0 1 0 0 0 1 0 0 0 0
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 1 1 1 0 0 1 1 1 0 1 1 1 0 0
NB. 1 1 1 1 0 1 1 1 1 1 1 1 1 0
NB. 1 1 1 1 1 1 1 1 1
NB.
NB. 1 trlpick 4 5 $ 1 1 trlpick 5 4 $ 1 1 trlpick 5 5 $ 1
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 1 1 1 0 0 1 1 1 0 1 1 1 0 0
NB. 1 1 1 1 0 1 1 1 1 1 1 1 1 0
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 1 1 1 1 1 1 1 1 1
NB.
NB. _1 trlpick 4 5 $ 1 _1 trlpick 5 4 $ 1 _1 trlpick 5 5 $ 1
NB. 0 0 0 0 0 0 0 0 0 0 0 0 0 0
NB. 1 0 0 0 0 1 0 0 0 1 0 0 0 0
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 1 1 1 0 0 1 1 1 0 1 1 1 0 0
NB. 1 1 1 1 1 1 1 1 0
trlpick=: (>: ft4lisoa)`(0&,:)} :(4 : '((__ , x) mbstencil ])`(0 ,: ])} y')
NB. ---------------------------------------------------------
NB. trupick
NB.
NB. Description:
NB. Zeroize elements outside upper trapezoidal part of the
NB. matrix
NB.
NB. Syntax:
NB. B=. [d] trupick A
NB. where
NB. A - m×n-matrix, contains B
NB. d - integer in range [-∞,+∞], lIO first non-zero
NB. diagonal, default is 0
NB. B - m×n-matrix, the upper trapezoidal
NB.
NB. Examples:
NB. trupick 4 5 $ 1 trupick 5 4 $ 1 trupick 5 5 $ 1
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 0 1 1 1 1 0 1 1 1 0 1 1 1 1
NB. 0 0 1 1 1 0 0 1 1 0 0 1 1 1
NB. 0 0 0 1 1 0 0 0 1 0 0 0 1 1
NB. 0 0 0 0 0 0 0 0 1
NB.
NB. 0 trupick 4 5 $ 1 0 trupick 5 4 $ 1 0 trupick 5 5 $ 1
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 0 1 1 1 1 0 1 1 1 0 1 1 1 1
NB. 0 0 1 1 1 0 0 1 1 0 0 1 1 1
NB. 0 0 0 1 1 0 0 0 1 0 0 0 1 1
NB. 0 0 0 0 0 0 0 0 1
NB.
NB. 1 trupick 4 5 $ 1 1 trupick 5 4 $ 1 1 trupick 5 5 $ 1
NB. 0 1 1 1 1 0 1 1 1 0 1 1 1 1
NB. 0 0 1 1 1 0 0 1 1 0 0 1 1 1
NB. 0 0 0 1 1 0 0 0 1 0 0 0 1 1
NB. 0 0 0 0 1 0 0 0 0 0 0 0 0 1
NB. 0 0 0 0 0 0 0 0 0
NB.
NB. _1 trupick 4 5 $ 1 _1 trupick 5 4 $ 1 _1 trupick 5 5 $ 1
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 0 1 1 1 1 0 1 1 1 0 1 1 1 1
NB. 0 0 1 1 1 0 0 1 1 0 0 1 1 1
NB. 0 0 0 1 0 0 0 1 1
trupick=: (<: ft4lisoa)`(0&,:)} :(4 : '((x , _) mbstencil ])`(0 ,: ])} y')
NB. ---------------------------------------------------------
NB. trl1pick
NB.
NB. Description:
NB. Zeroize elements outside lower trapezoidal part of the
NB. matrix and set diagonal to 1
NB.
NB. Syntax:
NB. B=. [d] trl1pick A
NB. where
NB. A - m×n-matrix, contains B
NB. d - integer in range [-∞,+∞], optional lIO last
NB. non-zero diagonal, default is 0
NB. B - m×n-matrix, the lower trapezoidal with unit on
NB. diagonal d
NB.
NB. Examples:
NB. trl1pick 4 5 $ 1 trl1pick 5 4 $ 1 trl1pick 5 5 $ 1
NB. 1 0 0 0 0 1 0 0 0 1 0 0 0 0
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 1 1 1 0 0 1 1 1 0 1 1 1 0 0
NB. 1 1 1 1 0 1 1 1 1 1 1 1 1 0
NB. 1 1 1 1 1 1 1 1 1
NB.
NB. 0 trl1pick 4 5 $ 1 0 trl1pick 5 4 $ 1 0 trl1pick 5 5 $ 1
NB. 1 0 0 0 0 1 0 0 0 1 0 0 0 0
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 1 1 1 0 0 1 1 1 0 1 1 1 0 0
NB. 1 1 1 1 0 1 1 1 1 1 1 1 1 0
NB. 1 1 1 1 1 1 1 1 1
NB.
NB. 1 trl1pick 4 5 $ 1 1 trl1pick 5 4 $ 1 1 trl1pick 5 5 $ 1
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 1 1 1 0 0 1 1 1 0 1 1 1 0 0
NB. 1 1 1 1 0 1 1 1 1 1 1 1 1 0
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 1 1 1 1 1 1 1 1 1
NB.
NB. _1 trl1pick 4 5 $ 1 _1 trl1pick 5 4 $ 1 _1 trl1pick 5 5 $ 1
NB. 0 0 0 0 0 0 0 0 0 0 0 0 0 0
NB. 1 0 0 0 0 1 0 0 0 1 0 0 0 0
NB. 1 1 0 0 0 1 1 0 0 1 1 0 0 0
NB. 1 1 1 0 0 1 1 1 0 1 1 1 0 0
NB. 1 1 1 1 1 1 1 1 0
trl1pick=: 0&$: :((1 ; [) setdiag trlpick)
NB. ---------------------------------------------------------
NB. tru1pick
NB.
NB. Description:
NB. Zeroize elements outside upper trapezoidal part of the
NB. matrix and set diagonal to 1
NB.
NB. Syntax:
NB. B=. [d] trupick A
NB. where
NB. A - m×n-matrix, contains B
NB. d - integer in range [-∞,+∞], optional lIO first
NB. non-zero diagonal, default is 0
NB. B - m×n-matrix, the upper trapezoidal with unit on
NB. diagonal d
NB.
NB. Examples:
NB. tru1pick 4 5 $ 1 tru1pick 5 4 $ 1 tru1pick 5 5 $ 1
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 0 1 1 1 1 0 1 1 1 0 1 1 1 1
NB. 0 0 1 1 1 0 0 1 1 0 0 1 1 1
NB. 0 0 0 1 1 0 0 0 1 0 0 0 1 1
NB. 0 0 0 0 0 0 0 0 1
NB.
NB. 0 tru1pick 4 5 $ 1 0 tru1pick 5 4 $ 1 0 tru1pick 5 5 $ 1
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 0 1 1 1 1 0 1 1 1 0 1 1 1 1
NB. 0 0 1 1 1 0 0 1 1 0 0 1 1 1
NB. 0 0 0 1 1 0 0 0 1 0 0 0 1 1
NB. 0 0 0 0 0 0 0 0 1
NB.
NB. 1 tru1pick 4 5 $ 1 1 tru1pick 5 4 $ 1 1 tru1pick 5 5 $ 1
NB. 0 1 1 1 1 0 1 1 1 0 1 1 1 1
NB. 0 0 1 1 1 0 0 1 1 0 0 1 1 1
NB. 0 0 0 1 1 0 0 0 1 0 0 0 1 1
NB. 0 0 0 0 1 0 0 0 0 0 0 0 0 1
NB. 0 0 0 0 0 0 0 0 0
NB.
NB. _1 tru1pick 4 5 $ 1 _1 tru1pick 5 4 $ 1 _1 tru1pick 5 5 $ 1
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 1 1 1 1 1 1 1 1 1 1 1 1 1 1
NB. 0 1 1 1 1 0 1 1 1 0 1 1 1 1
NB. 0 0 1 1 1 0 0 1 1 0 0 1 1 1
NB. 0 0 0 1 0 0 0 1 1
tru1pick=: 0&$: :((1 ; [) setdiag trupick)
NB. ---------------------------------------------------------
NB. idmat
NB.
NB. Description:
NB. Make identity matrix with units on solid part of
NB. diagonal
NB.
NB. Syntax:
NB. I=. [(d[,h[,s]])] idmat [m,]n
NB. where
NB. m ≥ 0, integer, optional rows in matrix I, default is n
NB. n ≥ 0, integer, columns in matrix I
NB. d - integer in range [1-m,n-1], optional lIO diagonal,
NB. default is 0 (main diagonal)
NB. h - integer in range [-S,S-1], optional lIO extreme
NB. element of solid part of diagonal, default is 0
NB. (take from head)
NB. s - integer in range [-S,S] or ±∞, optional size of
NB. solid part of diagonal, default is +∞ (all elements
NB. in forward direction)
NB. I - m×n-matrix of zeros with unit assigned to solid
NB. part of d-th diagonal
NB. S ≥ 0, the length of d-th diagonal
NB.
NB. Examples:
NB. idmat 3 idmat 3 4
NB. 1 0 0 1 0 0 0
NB. 0 1 0 0 1 0 0
NB. 0 0 1 0 0 1 0
NB.
NB. 1 idmat 3 4 _1 idmat 3 4
NB. 0 1 0 0 0 0 0 0
NB. 0 0 1 0 1 0 0 0
NB. 0 0 0 1 0 1 0 0
NB.
NB. TODO:
NB. - I would be sparse
idmat=: a:&$: :((1 ; [) setdiag (0 $~ 2 $ ]))
NB. ---------------------------------------------------------
NB. diagmat
NB.
NB. Description:
NB. Make diagonal matrix
NB.
NB. Syntax:
NB. D=. [(h,t)] diagmat e
NB. where
NB. e - S-vector, new values for diagonal
NB. h - integer in range [1-m,n-1], optional lIO diagonal
NB. of v's head, relatively to top left corner, default
NB. is 0
NB. t - integer in range [1-m,n-1], optional lIO diagonal
NB. of v's tail, relatively to bottom right corner,
NB. default is 0
NB. D - m×n-matrix of zeros with vector e assigned to h-th
NB. diagonal
NB. S ≥ 0, the length of h-th diagonal