-
Notifications
You must be signed in to change notification settings - Fork 0
/
tri.ijs
1030 lines (959 loc) · 35.7 KB
/
tri.ijs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
NB. Inverse by triangular factorization
NB.
NB. trtrixx Inverse triangular matrix
NB. getrixxxx Inverse general matrix
NB. hetripx Inverse Hermitian (symmetric) matrix
NB. potrix Inverse Hermitian (symmetric) positive
NB. definite matrix
NB. pttrix Inverse Hermitian (symmetric) positive
NB. definite tridiagonal matrix
NB.
NB. testtrtri Test trtrixx by triangular matrix
NB. testgetri Test getrixxxx by square matrix
NB. testhetri Test hetripx by Hermitian (symmetric) matrix
NB. testpotri Test potrix by Hermitian (symmetric) positive
NB. definite matrix
NB. testpttri Test pttrix by Hermitian (symmetric) positive
NB. definite tridiagonal matrix
NB. testtri Adv. to make verb to test xxtrixxxx by matrix
NB. of generator and shape given
NB.
NB. Copyright 2010,2011,2013,2017,2018,2020,2021,2023,2024
NB. Igor Zhuravlov
NB.
NB. This file is part of mt
NB.
NB. mt is free software: you can redistribute it and/or
NB. modify it under the terms of the GNU Lesser General
NB. Public License as published by the Free Software
NB. Foundation, either version 3 of the License, or (at your
NB. option) any later version.
NB.
NB. mt is distributed in the hope that it will be useful, but
NB. WITHOUT ANY WARRANTY; without even the implied warranty
NB. of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
NB. See the GNU Lesser General Public License for more
NB. details.
NB.
NB. You should have received a copy of the GNU Lesser General
NB. Public License along with mt. If not, see
NB. <http://www.gnu.org/licenses/>.
NB. =========================================================
NB. Configuration
coclass 'mt'
NB. =========================================================
NB. Local definitions
NB. ---------------------------------------------------------
NB. Blocked code constants
TRINB=: 64 NB. block size limit
NB. ---------------------------------------------------------
NB. getrilu1pstep
NB.
NB. Description:
NB. Single step of non-blocked version of getrilu1p
NB.
NB. Syntax:
NB. 'pfxi1 sfxi1'=. getrilu1pstep (pfxi ; sfxi)
NB. where
NB. pfxi - (j+TRINB)×n-matrix after i-th step and before
NB. (i+1)-th one, contains not yet processed part
NB. sfxi - (n-j-TRINB)×n-matrix after i-th step and before
NB. (i+1)-th one, contains already processed part
NB. pfxi1 - j×n-matrix, being pfxi after (i+1)-th step
NB. sfxi1 - (n-j)×n-matrix, being sfxi after (i+1)-th step
NB. j = (I-(i+1))*TRINB
NB. i = 0:I-1
NB. I = ⌊n/TRINB⌋
NB.
NB. Algorithm:
NB. In:
NB. pfx(i) := A[0:j+TRINB-1,0:n-1]
NB. sfx(i) := A[j+TRINB:n-1,0:n-1]
NB. Out:
NB. pfx(i+1) := A[0:j-1,0:n-1]
NB. sfx(i+1) := A[j:n-1,0:n-1]
NB. 1) extract current diagonal block of A(i) from pfx(i):
NB. U0i := A[j:j+TRINB-1,j:j+TRINB-1] ,
NB. it contains merged current diagonal blocks of L^_1
NB. and U1
NB. 2) extract current subdiagonal block row of U1 from
NB. pfx(i):
NB. U1i := A[j:j+TRINB-1,j+TRINB:n-1]
NB. 3) extract current block row of L^_1 from pfx(i):
NB. 3.1) extract current block row of A(i):
NB. Ri := A[j:j+TRINB-1,0:n-1] ,
NB. it contains merged current row blocks of
NB. L^_1 and U1
NB. 3.2) zeroize in Ri elements behind the main diagonal
NB. 4) update Ri:
NB. 4.1) do:
NB. Ri := Ri - U1i * sfx(i)
NB. 4.2) solve:
NB. Riupd * U0i = Ri
NB. for Riupd, where U0i is unit upper triangular
NB. 5) assemble output:
NB. 5.1) cut off current block row from pfx(i) to
NB. produce pfx(i+1)
NB. 5.2) append sfx(i) to Riupd to produce sfx(i+1)
NB. 5.3) link sfx(i+1) to pfx(i+1)
getrilu1pstep=: 3 : 0
'pfx sfx'=. y
'j n'=. $ pfx
j=. j - TRINB
U0i=. (,.~ j , TRINB) (];.0) pfx
U1i=. (- TRINB , # sfx) {. pfx
Ri=. (-TRINB) {. pfx
Ri=. ((i. TRINB) </ (i. n) - j)} Ri ,: 0 NB. spec code
Ri=. Ri - U1i mp sfx
Ri=. U0i trsmlunu Ri
((-TRINB) }. pfx) ; Ri , sfx
)
NB. ---------------------------------------------------------
NB. getripl1ustep
NB.
NB. Description:
NB. Single step of non-blocked version of getripl1u
NB.
NB. Syntax:
NB. 'pfxi1 sfxi1'=. getripl1ustep (pfxi ; sfxi)
NB. where
NB. pfxi - n×(j+TRINB)-matrix after i-th step and before
NB. (i+1)-th one, contains not yet processed part
NB. sfxi - n×(n-j-TRINB)-matrix after i-th step and before
NB. (i+1)-th one, contains already processed part
NB. pfxi1 - n×j-matrix, being pfxi after (i+1)-th step
NB. sfxi1 - n×(n-j)-matrix, being sfxi after (i+1)-th step
NB. j = (I-(i+1))*TRINB
NB. i = 0:I-1
NB. I = ⌊n/TRINB⌋
NB.
NB. Algorithm:
NB. In:
NB. pfx(i) := A[0:n-1,0:j+TRINB-1]
NB. sfx(i) := A[0:n-1,j+TRINB:n-1]
NB. Out:
NB. pfx(i+1) := A[0:n-1,0:j-1]
NB. sfx(i+1) := A[0:n-1,j:n-1]
NB. 1) extract current diagonal block of A(i) from pfx(i):
NB. L0i := A[j:j+TRINB-1,j:j+TRINB-1] ,
NB. it contains merged current diagonal blocks of U^_1
NB. and L1
NB. 2) extract current subdiagonal block column of L1 from
NB. pfx(i):
NB. L1i := A[j+TRINB:n-1,j:j+TRINB-1]
NB. 3) extract current block column of U^_1 from pfx(i):
NB. 3.1) extract current block column of A(i):
NB. Ci := A[0:n-1,j:j+TRINB-1] ,
NB. it contains merged current column blocks of
NB. U^_1 and L1
NB. 3.2) zeroize in Ci elements under main diagonal
NB. 4) update Ci:
NB. 4.1) do:
NB. Ci := Ci - sfx(i) * L1i
NB. 4.2) solve:
NB. Ciupd * L0i = Ci
NB. for Ciupd, where L0i is unit lower triangular
NB. 5) assemble output:
NB. 5.1) cut off current block column from pfx(i) to
NB. produce pfx(i+1)
NB. 5.2) stitch sfx(i) to Ciupd to produce sfx(i+1)
NB. 5.3) link sfx(i+1) to pfx(i+1)
NB.
NB. References:
NB. [1] J. DuCroz, Nicholas J. Higham. Stability of Methods
NB. for Matrix Inversion. UT-CS-90-119, October, 1990.
NB. LAPACK Working Note 27.
NB. http://www.netlib.org/lapack/lawns/downloads/
getripl1ustep=: 3 : 0
'pfx sfx'=. y
'n j'=. $ pfx
j=. j - TRINB
L0i=. (,.~ j , TRINB) (];.0) pfx
L1i=. (- (c sfx),TRINB) {. pfx
Ci=. (-TRINB) ({."1) pfx
Ci=. (((i. n) - j) >/ i. TRINB)} Ci ,: 0 NB. spec code
Ci=. Ci - sfx mp L1i
Ci=. L0i trsmrlnu Ci
((-TRINB) (}."1) pfx) ; Ci ,. sfx
)
NB. ---------------------------------------------------------
NB. getripu1lstep
NB.
NB. Description:
NB. Single step of non-blocked version of getripu1l
NB.
NB. Syntax:
NB. 'pfxi1 sfxi1'=. getripu1lstep (pfxi ; sfxi)
NB. where
NB. pfxi - n×j-matrix after i-th step and before
NB. (i+1)-th one, contains already processed part
NB. sfxi - n×(n-j)-matrix after i-th step and before
NB. (i+1)-th one, contains not yet processed part
NB. pfxi1 - n×(j+TRINB)-matrix, being pfxi after (i+1)-th
NB. step
NB. sfxi1 - n×(n-j-TRINB)-matrix, being sfxi after (i+1)-th
NB. step
NB. j = n-(I-i)*TRINB
NB. i = 0:I-1
NB. I = ⌊n/TRINB⌋
NB.
NB. Algorithm:
NB. In:
NB. pfx(i) := A[0:n-1,0:j-1]
NB. sfx(i) := A[0:n-1,j:n-1]
NB. Out:
NB. pfx(i+1) := A[0:n-1,0:j+TRINB-1]
NB. sfx(i+1) := A[0:n-1,j+TRINB:n-1]
NB. 1) extract current diagonal block of A(i) from sfx(i):
NB. U0i := A[j:j+TRINB-1,j:j+TRINB-1] ,
NB. it contains merged current diagonal blocks of L^_1
NB. and U1
NB. 2) extract current superdiagonal block column of U1
NB. from sfx(i):
NB. U1i := A[0:j-1,j:j+TRINB-1]
NB. 3) extract current block column of L^_1 from sfx(i):
NB. 3.1) extract current block column of A(i):
NB. Ri := A[0:n-1,j:j+TRINB-1] ,
NB. it contains merged current column blocks of
NB. L^_1 and U1
NB. 3.2) zeroize in Ci elements above the main diagonal
NB. 4) update Ci:
NB. 4.1) do:
NB. Ci := Ci - sfx(i) * U1i
NB. 4.2) solve:
NB. U0i * Ciupd = Ci
NB. for Ciupd, where U0i is unit upper triangular
NB. 5) assemble output:
NB. 5.1) cut off current block column from sfx(i) to
NB. produce sfx(i+1)
NB. 5.2) stitch Ciupd to pfx(i) to produce pfx(i+1)
NB. 5.3) link sfx(i+1) to pfx(i+1)
getripu1lstep=: 3 : 0
'pfx sfx'=. y
'n j'=. $ pfx
U0i=. ((j , 0) ,: 2 # TRINB) (];.0) sfx
U1i=. (j , TRINB) {. sfx
Ci=. TRINB ({."1) sfx
Ci=. (((i. n) - j) </ i. TRINB)} Ci ,: 0 NB. spec code
Ci=. Ci - pfx mp U1i
Ci=. U0i trsmrunu Ci
(pfx ,. Ci) ; TRINB (}."1) sfx
)
NB. ---------------------------------------------------------
NB. getriul1pstep
NB.
NB. Description:
NB. Single step of non-blocked version of getriul1p
NB.
NB. Syntax:
NB. 'pfxi1 sfxi1'=. getristep (pfxi ; sfxi)
NB. where
NB. pfxi - j×n-matrix after i-th step and before
NB. (i+1)-th one, contains already processed part
NB. sfxi - (n-j)×n-matrix after i-th step and before
NB. (i+1)-th one, contains not yet processed part
NB. pfxi1 - (j+TRINB)×n-matrix, being pfx(i) after (i+1)-th
NB. step
NB. sfxi1 - (n-j-TRINB)×n-matrix, being sfx(i) after
NB. (i+1)-th step
NB. j = n-(I-i)*TRINB
NB. i = 0:I-1
NB. I = ⌊n/TRINB⌋
NB.
NB. Algorithm:
NB. In:
NB. pfx(i) := A[0:j-1,0:n-1]
NB. sfx(i) := A[j:n-1,0:n-1]
NB. Out:
NB. pfx(i+1) := A[0:j+TRINB-1,0:n-1]
NB. sfx(i+1) := A[j+TRINB:n-1,0:n-1]
NB. 1) extract current diagonal block of A(i) from sfx(i):
NB. L0i := A[j:j+TRINB-1,j:j+TRINB-1] ,
NB. it contains merged current diagonal blocks of U^_1
NB. and L1
NB. 2) extract current subdiagonal block row of L1 from
NB. sfx(i):
NB. L1i := A[j:j+TRINB-1,0:j-1]
NB. 3) extract current block row of U^_1 from sfx(i):
NB. 3.1) extract current block row of A(i):
NB. Ri := A[j:j+TRINB-1,0:n-1] ,
NB. it contains merged current row blocks of U^_1
NB. and L1
NB. 3.2) zeroize in Ri elements to the left of the main
NB. diagonal
NB. 4) update Ri:
NB. 4.1) do:
NB. Ri := Ri - L1i * pfx(i)
NB. 4.2) solve:
NB. L0i * Riupd = Ri
NB. for Riupd, where L0i is unit lower triangular
NB. 5) assemble output:
NB. 5.1) cut off current block row from sfx(i) to
NB. produce sfx(i+1)
NB. 5.2) append Riupd to pfx(i) to produce pfx(i+1)
NB. 5.3) link sfx(i+1) to pfx(i+1)
getriul1pstep=: 3 : 0
'pfx sfx'=. y
'j n'=. $ pfx
L0i=. ((0 , j) ,: 2 # TRINB) (];.0) sfx
L1i=. (TRINB , j) {. sfx
Ri=. TRINB {. sfx
Ri=. ((i. TRINB) >/ (i. n) - j)} Ri ,: 0 NB. spec code
Ri=. Ri - L1i mp pfx
Ri=. L0i trsmllnu Ri
(pfx , Ri) ; TRINB }. sfx
)
NB. =========================================================
NB. Interface
NB. ---------------------------------------------------------
NB. Verb Syntax
NB. trtril iL=. trtril L
NB. trtril1 iL1=. trtril1 L1
NB. trtriu iU=. trtriu U
NB. trtriu1 iU1=. trtriu1 U1
NB.
NB. Description:
NB. Inverse triangular matrix
NB. where
NB. L - n×n-matrix, the lower triangular
NB. iL - n×n-matrix, the lower triangular, an inversion of
NB. L
NB. L1 - n×n-matrix, the unit lower triangular (unit
NB. diagonal is not stored)
NB. iL1 - n×n-matrix, the unit lower triangular (unit
NB. diagonal is not stored), the inversion of L1
NB. U - n×n-matrix, the upper triangular
NB. iU - n×n-matrix, the upper triangular, the inversion
NB. of U
NB. U1 - n×n-matrix, the unit upper triangular (unit
NB. diagonal is not stored)
NB. iU1 - n×n-matrix, the unit upper triangular (unit
NB. diagonal is not stored), the inversion of U1
NB.
NB. Algorithm for trtriu:
NB. In: U
NB. Out: iU
NB. 1) if 1 < # U
NB. 1.1) then
NB. 1.1.1) form (#U)-vector fret:
NB. fret[:] := 0
NB. fret[0] := 1
NB. fret[k] := 1
NB. where k is splitting edge:
NB. k := ⌈n/2⌉
NB. 1.1.2) cut U by fret to block matrix bU:
NB. bU := ( U00 ) k
NB. ( U10 U11 ) n-k
NB. k n-k
NB. 1.1.3) apply trtriu itself to U00 and U11:
NB. iU00 := U00^_1
NB. iU11 := U11^_1
NB. 1.1.4) replace U00 and U11 by iU00 and iU11,
NB. respectively, in bU
NB. 1.1.5) inverse U01:
NB. iU01 := - iU00 * U01 * iU11
NB. 1.1.6) replace U01 by iU01 in bU
NB. 1.1.7) assemble iU from block matrix:
NB. iU=. icut bU
NB. 1.2) else return reciprocal:
NB. iU=. % U
NB.
NB. Notes:
NB. - unit diagonal is not referenced
NB. - models LAPACK's xTRTRI with following differences:
NB. - blocked not partitioned algorithm is used
NB. - opposite triangle must be zeroed
NB.
NB. TODO:
NB. - fret would be sparse
trtril=: % `(icut@(2:}~ <@:-@((1 1 {:: ]) mp (1 0 {:: ]) mp 0 0 {:: ]))@(<@$:`<`<;.1~ ;~@(1:`]`([ ($!.0) 1:)} (>.@-:))@#))@.(1 < #)
trtril1=: (1"0)`(icut@(2:}~ <@:-@((1 1 {:: ]) mp (1 0 {:: ]) mp 0 0 {:: ]))@(<@$:`<`<;.1~ ;~@(1:`]`([ ($!.0) 1:)} (>.@-:))@#))@.(1 < #)
trtriu=: % `(icut@(1:}~ <@:-@((0 0 {:: ]) mp (0 1 {:: ]) mp 1 1 {:: ]))@(<@$:`<`<;.1~ ;~@(1:`]`([ ($!.0) 1:)} (>.@-:))@#))@.(1 < #)
trtriu1=: (1"0)`(icut@(1:}~ <@:-@((0 0 {:: ]) mp (0 1 {:: ]) mp 1 1 {:: ]))@(<@$:`<`<;.1~ ;~@(1:`]`([ ($!.0) 1:)} (>.@-:))@#))@.(1 < #)
NB. ---------------------------------------------------------
NB. getrilu1p
NB.
NB. Description:
NB. Inverse a general matrix A, represented in factored
NB. form:
NB. L * U1 * P = A
NB.
NB. Syntax:
NB. iA=. getrilu1p LU1p
NB. where
NB. LU1p - 2-vector of boxes, the output of getrflu1p, the
NB. matrix A represented in factored form
NB. iA - n×n-matrix, an inversion of A
NB. A - n×n-matrix
NB.
NB. Algorithm:
NB. In: LU1p
NB. Out: iA
NB. 1) extract ip and LU1 from LU1p
NB. 2) acquire n, the size of A
NB. 3) extract L from LU1, inverse it and save L^_1 into y
NB. 4) copy U1 from LU1 into the strict upper triangle of y
NB. 5) calculate the number of iterations of partitioned
NB. algorithm:
NB. I := ⌊n/TRINB⌋
NB. note: partitioned algorithm will be applied to the
NB. first I*TRINB rows of y
NB. 6) invert A:
NB. 6.1) prepare suffix sfx from the last n%TRINB rows
NB. of y, which won't be processed by partitioned
NB. algorithm
NB. 6.1.1) extract last n%TRINB rows from L^_1:
NB. iLsfx := L^_1[I*TRINB:n-1,0:n-1]
NB. 6.1.2) extract unit upper triangular matrix
NB. from last n%TRINB rows of U1:
NB. U1sfx := U1[I*TRINB:n-1,I*TRINB:n-1]
NB. 6.1.3) solve system
NB. U1sfx * sfx = iLsfx
NB. for sfx, where
NB. sfx := A^_1[I*TRINB:n-1,0:n-1]
NB. is the last n%TRINB rows of A^_1
NB. 6.2) prepare prefix pfx - the 1st I*TRINB rows of y,
NB. which will be processed by partitioned
NB. algorithm:
NB. pfx := A[0:I*TRINB-1,0:n-1]
NB. 6.3) do iterations i=0:I-1 :
NB. 'pfx sfx'=. getrilu1pstep^:I (pfx ; sfx)
NB. 6.4) extract sfx produced by the last iteration
NB. 6.5) apply permutation P to rows of sfx by obversed
NB. applying of inversed permutation P^H, to
NB. produce final A^_1
NB.
NB. Assertions:
NB. (%. -: (getrilu1p@getrflu1p)) A
getrilu1p=: 3 : 0
'ip LU1'=. y
n=. c LU1
y=. trtril trl LU1
y=. y lxsuy LU1
I=. <. n % TRINB
ip (C.^:_1) 1 {:: getrilu1pstep^:I (TRINB * I) ({. ; ([ (tru1 trsmlunu trl) }.)) y
)
NB. ---------------------------------------------------------
NB. getripl1u
NB.
NB. Description:
NB. Inverse a general matrix A, represented in factored
NB. form [1]:
NB. P * L1 * U = A
NB.
NB. Syntax:
NB. iA=. getripl1u pL1U
NB. where
NB. pL1U - 2-vector of boxes, the output of getrfpl1u, the
NB. matrix A represented in factored form
NB. iA - n×n-matrix, an inversion of A
NB. A - n×n-matrix
NB.
NB. Algorithm:
NB. In: pL1U
NB. Out: iA
NB. 1) extract ip and L1U from pL1U
NB. 2) acquire n, the size of A
NB. 3) extract U from L1U, inverse it and save U^_1 into y
NB. 4) copy L1 from L1U into the strict lower triangle of y
NB. 5) calculate the number of iterations of partitioned
NB. algorithm:
NB. I := ⌊n/TRINB⌋
NB. note: partitioned algorithm will be applied to the
NB. first I*TRINB columns of y
NB. 6) invert A:
NB. 6.1) prepare suffix sfx from the last n%TRINB columns
NB. of y, which won't be processed by partitioned
NB. algorithm
NB. 6.1.1) extract last n%TRINB columns from U^_1:
NB. iUsfx := U^_1[0:n-1,I*TRINB:n-1]
NB. 6.1.2) extract unit lower triangular matrix
NB. from last n%TRINB columns of L1:
NB. L1sfx := L1[I*TRINB:n-1,I*TRINB:n-1]
NB. 6.1.3) solve system
NB. sfx * L1sfx = iUsfx
NB. for sfx, where
NB. sfx := A^_1[0:n-1,I*TRINB:n-1]
NB. is the last n%TRINB columns of A^_1
NB. 6.2) prepare prefix pfx - the 1st I*TRINB columns of
NB. y, which will be processed by partitioned
NB. algorithm:
NB. pfx := A[0:n-1,0:I*TRINB-1]
NB. 6.3) do iterations i=0:I-1 :
NB. 'pfx sfx'=. getripl1ustep^:I (pfx ; sfx)
NB. 6.4) extract sfx produced by the last iteration
NB. 6.5) apply permutation P to columns of sfx by
NB. obversed applying of inversed permutation P^H,
NB. to produce final A^_1
NB.
NB. Assertions:
NB. (%. -: (getripl1u@getrfpl1u)) A
NB.
NB. Notes:
NB. - implements LAPACK's xGETRI
NB.
NB. References:
NB. [1] J. DuCroz, Nicholas J. Higham. Stability of Methods
NB. for Matrix Inversion. UT-CS-90-119, October, 1990.
NB. LAPACK Working Note 27.
NB. http://www.netlib.org/lapack/lawns/downloads/
getripl1u=: 3 : 0
'ip L1U'=. y
n=. # L1U
y=. trtriu tru L1U
y=. y uxsly L1U
I=. <. n % TRINB
ip (C.^:_1"1) 1 {:: getripl1ustep^:I (TRINB * I) (({."1) ; ((-@[) (trl1 trsmrlnu tru) (}."1))) y
)
NB. ---------------------------------------------------------
NB. getripu1l
NB.
NB. Description:
NB. Inverse a general matrix A, represented in factored
NB. form:
NB. P * U1 * L = A
NB.
NB. Syntax:
NB. iA=. getripu1l pU1L
NB. where
NB. pU1L - 2-vector of boxes, the output of getrfpu1l, the
NB. matrix A represented in factored form
NB. iA - n×n-matrix, an inversion of A
NB. A - n×n-matrix
NB.
NB. Algorithm:
NB. In: pU1L
NB. Out: iA
NB. 1) extract ip and U1L from pU1L
NB. 2) acquire n, the size of A
NB. 3) extract L from U1L, inverse it and save L^_1 into y
NB. 4) copy U1 from U1L into the strict upper triangle of y
NB. 5) calculate the number of iterations of partitioned
NB. algorithm:
NB. I := ⌊n/TRINB⌋
NB. note: partitioned algorithm will be applied to the
NB. last I*TRINB columns of y
NB. 6) invert A:
NB. 6.1) prepare prefix pfx from the 1st n%TRINB columns
NB. of y, which won't be processed by partitioned
NB. algorithm
NB. 6.1.1) extract 1st n%TRINB columns from L^_1:
NB. iLpfx := L^_1[0:n-1,0:n%TRINB-1]
NB. 6.1.2) extract unit upper triangular matrix
NB. from 1st n%TRINB columns of U1:
NB. U1pfx := U1[0:n%TRINB-1,0:n%TRINB-1]
NB. 6.1.3) solve system
NB. pfx * U1pfx = iLpfx
NB. for pfx, where
NB. pfx := A^_1[0:n-1,0:n%TRINB-1]
NB. is the 1st n%TRINB columns of A^_1
NB. 6.2) prepare suffix sfx - the last I*TRINB columns
NB. of y, which will be processed by partitioned
NB. algorithm:
NB. sfx := A[0:n-1,n%TRINB:n-1]
NB. 6.3) do iterations i=0:I-1 :
NB. 'pfx sfx'=. getripu1lstep^:I (pfx ; sfx)
NB. 6.4) extract pfx produced by the last iteration
NB. 6.5) apply permutation P to columns of pfx by
NB. obversed applying of inversed permutation P^H,
NB. to produce final A^_1
NB.
NB. Assertions:
NB. (%. -: (getripu1l@getrfpu1l)) A
getripu1l=: 3 : 0
'ip U1L'=. y
n=. c U1L
y=. trtril trl U1L
y=. y lxsuy U1L
I=. <. n % TRINB
ip (C.^:_1"1) 0 {:: getripu1lstep^:I (TRINB | n) ((((2 # [) {. ]) trsmrunu trl@:({."1)) ; (}."1)) y
)
NB. ---------------------------------------------------------
NB. getriul1p
NB.
NB. Description:
NB. Inverse a general matrix A, represented in factored
NB. form:
NB. U * L1 * P = A
NB.
NB. Syntax:
NB. iA=. getriul1p UL1p
NB. where
NB. UL1p - 2-vector of boxes, the output of getrful1p, the
NB. matrix A represented in factored form
NB. iA - n×n-matrix, an inversion of A
NB. A - n×n-matrix
NB.
NB. Algorithm:
NB. In: UL1p
NB. Out: iA
NB. 1) extract ip and UL1 from UL1p
NB. 2) acquire n, the size of A
NB. 3) extract U from UL1, inverse it and save U^_1 into y
NB. 4) copy L1 from UL1 into the strict lower triangle of y
NB. 5) calculate the number of iterations of partitioned
NB. algorithm:
NB. I := ⌊n/TRINB⌋
NB. note: partitioned algorithm will be applied to the
NB. last I*TRINB rows of y
NB. 6) invert A:
NB. 6.1) prepare prefix pfx from the 1st n%TRINB rows of
NB. y, which won't be processed by partitioned
NB. algorithm
NB. 6.1.1) extract 1st n%TRINB rows from U^_1:
NB. iUpfx := U^_1[0:n%TRINB-1,0:n-1]
NB. 6.1.2) extract unit lower triangular matrix
NB. from 1st n%TRINB rows of L1:
NB. L1pfx := L1[0:n%TRINB-1,0:n%TRINB-1]
NB. 6.1.3) solve system
NB. L1pfx * pfx = iUpfx
NB. for pfx, where
NB. pfx := A^_1[0:n%TRINB-1,0:n-1]
NB. is the 1st n%TRINB rows of A^_1
NB. 6.2) prepare suffix sfx - the last I*TRINB rows of
NB. y, which will be processed by partitioned
NB. algorithm:
NB. sfx := A[n%TRINB:n-1,0:n-1]
NB. 6.3) do iterations i=0:I-1 :
NB. 'pfx sfx'=. getriul1pstep^:I (pfx ; sfx)
NB. 6.4) extract pfx produced by the last iteration
NB. 6.5) apply permutation P to rows of pfx by obversed
NB. applying of inversed permutation P^H, to
NB. produce final A^_1
NB.
NB. Assertions:
NB. (%. -: (getriul1p@getrful1p)) A
getriul1p=: 3 : 0
'ip UL1'=. y
n=. # UL1
y=. trtriu tru UL1
y=. y uxsly UL1
I=. <. n % TRINB
ip (C.^:_1) 0 {:: getriul1pstep^:I (TRINB | n) ((((2 # [) {. ]) trsmllnu tru@{.) ; }.) y
)
NB. ---------------------------------------------------------
NB. Verb Factorization used Syntax
NB. hetripl P * L1 * T * L1^H * P^H = A iA=. hetripl pL1T
NB. hetripu P * U1 * T * U1^H * P^H = A iA=. hetripu pU1T
NB.
NB. Description:
NB. Inverse Hermitian (symmetric) matrix A, represented in
NB. factored form
NB. where
NB. A - n×n-matrix, the Hermitian (symmetric)
NB. pL1T - 3-vector of boxes, the output of hetrfpl, the
NB. matrix A represented in factored form
NB. pU1T - 3-vector of boxes, the output of hetrfpu, the
NB. matrix A represented in factored form
NB. iA - n×n-matrix, an inversion of A
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. iA -: %. A
NB. where
NB. iA=. hetripl hetrfpl A
NB. or
NB. iA=. hetripu hetrfpu A
NB.
NB. Notes:
NB. - is similar to LAPACK's DSYTRI and ZHETRI, but uses
NB. another factorization, see hetrfx
hetripl=: 0&{:: fp^:_1 (gtsvax idmat@#)@(2&{::) (ct@] mp mp) trtril1@(1&{::)
hetripu=: 0&{:: fp^:_1 (gtsvax idmat@#)@(2&{::) (ct@] mp mp) trtriu1@(1&{::)
NB. ---------------------------------------------------------
NB. Verb Factorization used Syntax
NB. potril L * L^H = A iA=. potril L
NB. potriu U * U^H = A iA=. potriu U
NB.
NB. Description:
NB. Inverse Hermitian (symmetric) positive definite matrix
NB. A, represented in factored form
NB. where
NB. L - n×n-matrix, the output of potrfl, lower
NB. triangular Cholesky factor
NB. U - n×n-matrix, the output of potrfu, upper
NB. triangular Cholesky factor
NB. iA - n×n-matrix, an inversion of A
NB. A - n×n-matrix, the Hermitian (symmetric) positive
NB. definite
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. iA -: %. A
NB. where
NB. iA=. potril potrfl A
NB. or
NB. iA=. potriu potrfu A
NB.
NB. Notes:
NB. - potril models LAPACK's xPOTRI('L'), but uses direct,
NB. not iterative matrix product
potril=: (mp~ ct)@trtril
potriu=: (mp~ ct)@trtriu
NB. ---------------------------------------------------------
NB. Verb Factorization used Syntax
NB. pttril L1 * D * L1^H = A iA=. [L1D] pttril A
NB. pttriu U1 * D * U1^H = A iA=. [U1D] pttriu A
NB.
NB. Description:
NB. Inverse Hermitian (symmetric) positive definite
NB. tridiagonal matrix A, represented in factored form
NB. where
NB. L1D - 2-vector of boxes, the output of pttrfl, the
NB. matrix A represented in factored form, optional
NB. U1D - 2-vector of boxes, the output of pttrfu, the
NB. matrix A represented in factored form, optional
NB. iA - n×n-matrix, the inversion of A
NB. A - n×n-matrix, the Hermitian (symmetric) positive
NB. definite tridiagonal
NB.
NB. Algorithm for pttril [1]:
NB. In: A and, optionally, L1D
NB. Out: iA
NB. 1) if called monatically then:
NB. 1.1) factorize A:
NB. L1D=. pttrfl A
NB. 1.2) call itself dyadically:
NB. iA=. L1D $: A
NB. 2) else:
NB. 2.1) calculate Y:
NB. 2.1.1) extract 1st subdiagonal e from L1 and
NB. main diagonal d from D:
NB. 2.1.2) prepare iA[:,n-1]:
NB. q := conj(e) , 1/d[n-1]
NB. 2.1.3) update q by running products:
NB. q[j] := Π{q[j],j=n-1-j:n-1}
NB. via reversed infix scan
NB. 2.1.4) negate each q[j] for either even j
NB. if n is even, or odd j if n is odd:
NB. q[j] := q[j] * (-1)^(n+j+1)
NB. by negating each even element of
NB. reversed q[j]
NB. 2.1.5) stitch q, work around issue [2] for
NB. empty vector, to produce Y = iA[:,n-1]
NB. 2.2) calculate I:
NB. I := max(0,n-1)
NB. 2.3) calculate X:
NB. 2.3.1) extract 1st subdiagonal a and main
NB. diagonal b from A
NB. 2.3.2) form X:
NB. ( conj(a[ 0]) -b[ 1] -a[ 1] )
NB. ( conj(a[ 1]) -b[ 2] -a[ 2] )
NB. X := ( ... ... ... )
NB. ( conj(a[n-3]) -b[n-2] -a[n-2] )
NB. ( conj(a[n-2]) -b[n-1] 0 )
NB. 2.4) do iterations i=1:I by Power (^:):
NB. iA=. X step^:I Y
NB. each iteration takes iA[:,n-i:n-1] and produces
NB. iA[:,n-i-1:n-1]
NB. 2.4.1) find io:
NB. io := -i
NB. 2.4.2) find pi:
NB. pi := X[io,:]
NB. 2.4.3) calculate iA[:,n-i-1:n-1]
NB. 2.4.3.1) find new column iA[:,n-i-1]
NB. 2.4.3.2) stitch iA[:,n-i:n-1] to
NB. iA[:,n-i-1]
NB.
NB. Assertions (with appropriate comparison tolerance):
NB. iA -: %. A
NB. where
NB. iA=. pttril A
NB. or
NB. iA=. pttriu A
NB.
NB. TODO:
NB. - pttriu
NB. - A would be sparse
NB.
NB. References:
NB. [1] Moawwad El-Mikkawy, El-Desouky Rahmo. A new recursive
NB. algorithm for inverting general tridiagonal and
NB. anti-tridiagonal matrices. Applied Mathematics and
NB. Computation, 2008, Vol. 204, pp. 368-372.
NB. https://doi.org/10.1016/j.amc.2008.06.053
NB. [2] Igor Zhuravlov. [Jprogramming] ravel items (,.) of
NB. empty list (i.0)
NB. 2010-06-05 10:08:56 HKT
NB. http://jsoftware.com/pipermail/programming/2010-June/019617.html
pttril=: ($:~ pttrfl) : ((4 : 0)^:(((0:`(+@])`(_1&diag)`,.`((-@,. 1&(|.!.0))~ }.)`diag fork3)@])`(0>.<:@#@])`(empty`,.@.(0<#)@(]`-"0@(*/\)&.|.)@(((, %@(_1&{ :: ]))~ +)~&>/)@:(_1&diag&.>`(diag&.>)"0)@[)))
io=. -c y
pi=. io { x
(((>:&.(io&{)) (+/!.0"1) (}. pi) (*"1) (2 ({."1) y)) % {. pi) ,. y
)
NB. =========================================================
NB. Test suite
NB. ---------------------------------------------------------
NB. testtrtri
NB.
NB. Description:
NB. Test:
NB. - 128!:1 (built-in)
NB. - xTRTRI (math/lapack2)
NB. - trtrixx (math/mt addon)
NB. by triangular matrix
NB.
NB. Syntax:
NB. log=. testtrtri A
NB. where
NB. A - n×n-matrix
NB. log - 6-vector of boxes, test log
testtrtri=: 3 : 0
load_mttmp_ 'math/mt/external/lapack2/trtri'
rcondL=. trlcon1 L=. trlpick y
rcondU=. trucon1 U=. trupick y
rcondL1=. trl1con1 L1=. (1 ; '') setdiag L
rcondU1=. tru1con1 U1=. (1 ; '') setdiag U
norm1L=. norm1 L
norm1L1=. norm1 L1
norm1U=. norm1 U
norm1U1=. norm1 U1
log=. ('128!:1' tmonad ((0&{::)`] `(1&{::)`nan`t03)) U ; rcondU ; norm1U
log=. log lcat ('''ln''&dtrtri_mttmp_' tmonad ((3&{::)`trlpick `(1&{::)`nan`t03)) L ; rcondL ; norm1L ; y
log=. log lcat ('''lu''&dtrtri_mttmp_' tmonad ((3&{::)`trl1pick`(1&{::)`nan`t03)) L1 ; rcondL1 ; norm1L1 ; y
log=. log lcat ('''un''&dtrtri_mttmp_' tmonad ((3&{::)`trupick `(1&{::)`nan`t03)) U ; rcondU ; norm1U ; y
log=. log lcat ('''uu''&dtrtri_mttmp_' tmonad ((3&{::)`tru1pick`(1&{::)`nan`t03)) U1 ; rcondU1 ; norm1U1 ; y
log=. log lcat ('''ln''&ztrtri_mttmp_' tmonad ((3&{::)`trlpick `(1&{::)`nan`t03)) L ; rcondL ; norm1L ; y
log=. log lcat ('''lu''&ztrtri_mttmp_' tmonad ((3&{::)`trl1pick`(1&{::)`nan`t03)) L1 ; rcondL1 ; norm1L1 ; y
log=. log lcat ('''un''&ztrtri_mttmp_' tmonad ((3&{::)`trupick `(1&{::)`nan`t03)) U ; rcondU ; norm1U ; y
log=. log lcat ('''uu''&ztrtri_mttmp_' tmonad ((3&{::)`tru1pick`(1&{::)`nan`t03)) U1 ; rcondU1 ; norm1U1 ; y
log=. log lcat ('trtril' tmonad ((0&{::)`] `(1&{::)`nan`t03)) L ; rcondL ; norm1L
log=. log lcat ('trtril1' tmonad ((0&{::)`] `(1&{::)`nan`t03)) L1 ; rcondL1 ; norm1L1
log=. log lcat ('trtriu' tmonad ((0&{::)`] `(1&{::)`nan`t03)) U ; rcondU ; norm1U
log=. log lcat ('trtriu1' tmonad ((0&{::)`] `(1&{::)`nan`t03)) U1 ; rcondU1 ; norm1U1
coerase < 'mttmp'
log
)
NB. ---------------------------------------------------------
NB. testgetri
NB.
NB. Description:
NB. Test:
NB. - %. (built-in)
NB. - xGETRI (math/lapack2 addon)
NB. - getrixxxx (math/mt addon)
NB. by square matrix
NB.
NB. Syntax:
NB. log=. testgetri A
NB. where
NB. A - n×n-matrix
NB. log - 6-vector of boxes, test log
testgetri=: 3 : 0
load_mttmp_ 'math/mt/external/lapack2/getrf'
load_mttmp_ 'math/mt/external/lapack2/getri'
'rcondl rcondu'=. (geconi , gecon1) y
'norml normu'=. (normi , norm1) y
log=. ('%.' tmonad (( 0&{:: )`]`(1&{::)`nan`t03)) y ; rcondl ; norml
log=. log lcat ('dgetri_mttmp_' tmonad ((dgetrf_mttmp_@(0&{::))`]`(1&{::)`nan`t03)) y ; rcondu ; normu
log=. log lcat ('zgetri_mttmp_' tmonad ((zgetrf_mttmp_@(0&{::))`]`(1&{::)`nan`t03)) y ; rcondu ; normu
log=. log lcat ('getrilu1p' tmonad ((getrflu1p @(0&{::))`]`(1&{::)`nan`t03)) y ; rcondl ; norml
log=. log lcat ('getripl1u' tmonad ((getrfpl1u @(0&{::))`]`(1&{::)`nan`t03)) y ; rcondu ; normu
log=. log lcat ('getripu1l' tmonad ((getrfpu1l @(0&{::))`]`(1&{::)`nan`t03)) y ; rcondu ; normu
log=. log lcat ('getriul1p' tmonad ((getrful1p @(0&{::))`]`(1&{::)`nan`t03)) y ; rcondl ; norml
coerase < 'mttmp'
log
)
NB. ---------------------------------------------------------
NB. testhetri
NB.
NB. Description:
NB. Test:
NB. - DSYTRI2 ZHETRI2 (math/lapack2 addon)
NB. - hetripx (math/mt addon)
NB. by Hermitian (symmetric) matrix
NB.
NB. Syntax:
NB. log=. testhetri A
NB. where
NB. A - n×n-matrix, the Hermitian (symmetric)
NB. log - 6-vector of boxes, test log
testhetri=: 3 : 0
load_mttmp_ 'math/mt/external/lapack2/dsytrf'
load_mttmp_ 'math/mt/external/lapack2/dsytri2'
load_mttmp_ 'math/mt/external/lapack2/zhetrf'
load_mttmp_ 'math/mt/external/lapack2/zhetri2'
rcond=. heconi y
norm=. normi y
log=. ('''l''&dsytri2_mttmp_' tmonad (('l' dsytrf_mttmp_ 0&{:: )`he4gel`(1&{::)`nan`t03)) y ; rcond ; norm
log=. log lcat ('''u''&dsytri2_mttmp_' tmonad (('u' dsytrf_mttmp_ 0&{:: )`he4geu`(1&{::)`nan`t03)) y ; rcond ; norm
log=. log lcat ('''l''&zhetri2_mttmp_' tmonad (('l' zhetrf_mttmp_ 0&{:: )`he4gel`(1&{::)`nan`t03)) y ; rcond ; norm
log=. log lcat ('''u''&zhetri2_mttmp_' tmonad (('u' zhetrf_mttmp_ 0&{:: )`he4geu`(1&{::)`nan`t03)) y ; rcond ; norm
log=. log lcat ('hetripl' tmonad (( hetrfpl @(0&{::))`] `(1&{::)`nan`t03)) y ; rcond ; norm
log=. log lcat ('hetripu' tmonad (( hetrfpu @(0&{::))`] `(1&{::)`nan`t03)) y ; rcond ; norm
coerase < 'mttmp'
log
)
NB. ---------------------------------------------------------
NB. testpotri
NB.
NB. Description:
NB. Test:
NB. - xPOTRI (math/lapack2 addon)
NB. - potrix (math/mt addon)
NB. by Hermitian (symmetric) positive definite matrix
NB.
NB. Syntax:
NB. log=. testpotri A
NB. where
NB. A - n×n-matrix, the Hermitian (symmetric) positive
NB. definite
NB. log - 6-vector of boxes, test log
testpotri=: 3 : 0
load_mttmp_ 'math/mt/external/lapack2/potrf'
load_mttmp_ 'math/mt/external/lapack2/potri'
rcond=. pocon1 y
norm=. norm1 y
log=. ('''l''&dpotri_mttmp_' tmonad (('l' dpotrf_mttmp_ 0&{:: )`he4gel`(1&{::)`nan`t03)) y ; rcond ; norm
log=. log lcat ('''l''&zpotri_mttmp_' tmonad (('l' zpotrf_mttmp_ 0&{:: )`he4gel`(1&{::)`nan`t03)) y ; rcond ; norm
log=. log lcat ('potril' tmonad (( potrfl @(0&{::))`] `(1&{::)`nan`t03)) y ; rcond ; norm
log=. log lcat ('potriu' tmonad (( potrfu @(0&{::))`] `(1&{::)`nan`t03)) y ; rcond ; norm
coerase < 'mttmp'
log
)
NB. ---------------------------------------------------------
NB. testpttri
NB.
NB. Description:
NB. Test:
NB. - xPTTRI (math/lapack2 addon)
NB. - pttrix (math/mt addon)
NB. by Hermitian (symmetric) positive definite tridiagonal
NB. matrix
NB.
NB. Syntax:
NB. log=. testpttri A
NB. where
NB. A - n×n-matrix, the Hermitian (symmetric) positive
NB. definite tridiagonal
NB. log - 6-vector of boxes, test log
testpttri=: 3 : 0
rcond=. ptcon1 y
norm=. norm1 y
log=. ('pttril' tmonad (( 0&{:: ) `]`(1&{::)`nan`t03)) y ; rcond ; norm