-
Notifications
You must be signed in to change notification settings - Fork 1
/
cuteradio.pro
141 lines (95 loc) · 3.77 KB
/
cuteradio.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
TEMPLATE = app
TARGET = cuteradio
QT += network xml
INCLUDEPATH += src/base
HEADERS += src/base/*.h
SOURCES += src/base/*.cpp
maemo5 {
QT += declarative
INCLUDEPATH += src/maemo5
HEADERS += src/maemo5/*.h
SOURCES += src/maemo5/*.cpp
target.path = /opt/cuteradio/bin
qml.files = $$files(src/maemo5/qml/*.qml)
qml.path = /opt/cuteradio/qml
desktop.files = desktop/maemo5/cuteradio.desktop
desktop.path = /usr/share/applications/hildon
icon.files = desktop/maemo5/64x64/cuteradio.png
icon.path = /usr/share/icons/hicolor/64x64/apps
INSTALLS += qml desktop icon
} else:contains(MEEGO_EDITION,harmattan) {
CONFIG += qdeclarative-boostable
QT += declarative opengl
INCLUDEPATH += ../libcuteradio/src src/harmattan
HEADERS += ../libcuteradio/src/*.h src/harmattan/*.h
SOURCES += ../libcuteradio/src/*.cpp src/harmattan/*.cpp
target.path = /opt/cuteradio/bin
qml.files = $$files(src/harmattan/qml/*.qml)
qml.path = /opt/cuteradio/qml
images.files = $$files(src/harmattan/qml/images/*.png)
images.path = /opt/cuteradio/qml/images
desktop.files = desktop/harmattan/cuteradio.desktop
desktop.path = /usr/share/applications
icon.files = desktop/harmattan/80x80/cuteradio.png
icon.path = /usr/share/icons/hicolor/80x80/apps
splash.files = $$files(desktop/harmattan/splash/*.png)
splash.path = /opt/cuteradio/splash
INSTALLS += qml images desktop icon splash
} else:symbian {
TARGET = cuteradio_0xe71cbb8d
TARGET.UID3 = 0xE71CBB8D
TARGET.CAPABILITY += NetworkServices ReadUserData
TARGET.EPOCHEAPSIZE = 0x20000 0x8000000
TARGET.EPOCSTACKSIZE = 0x14000
VERSION = 0.4.2
ICON = desktop/symbian/cuteradio.svg
QT += declarative
CONFIG += qtcomponents
MMP_RULES += "DEBUGGABLE_UDEBONLY"
LIBS += -L\\epoc32\\release\\armv5\\lib -lremconcoreapi
LIBS += -L\\epoc32\\release\\armv5\\lib -lremconinterfacebase
INCLUDEPATH += MW_LAYER_SYSTEMINCLUDE ../libcuteradio/src src/symbian
HEADERS += ../libcuteradio/src/*.h src/symbian/*.h
SOURCES += ../libcuteradio/src/*.cpp src/symbian/*.cpp
vendorinfo += "%{\"Stuart Howarth\"}" ":\"Stuart Howarth\""
qtcomponentsdep = "; Default dependency to Qt Quick Components for Symbian library" \
"(0x200346DE), 1, 1, 0, {\"Qt Quick components for Symbian\"}"
cuteradio_deployment.pkg_prerules += vendorinfo qtcomponentsdep
qml.sources = $$files(src/symbian/qml/*.qml)
qml.path = !:/Private/e71cbb8d/qml
images.sources = $$files(src/symbian/qml/images/*.*)
images.path = !:/Private/e71cbb8d/qml/images
DEPLOYMENT.display_name = cuteRadio
DEPLOYMENT += cuteradio_deployment qml images
} else:unix {
greaterThan(QT_MAJOR_VERSION, 4) {
QT += widgets multimedia
}
else {
CONFIG += mobility
}
LIBS += -L/usr/lib -lcuteradio
CONFIG += link_prl
PKGCONFIG += libcuteradio
INCLUDEPATH += src/desktop
HEADERS += src/desktop/*.h
SOURCES += src/desktop/*.cpp
desktop.files = desktop/desktop/cuteradio.desktop
desktop.path = /usr/share/applications
icon64.files = desktop/desktop/64x64/cuteradio.png
icon64.path = /usr/share/icons/hicolor/64x64/apps
icon48.files = desktop/desktop/48x48/cuteradio.png
icon48.path = /usr/share/icons/hicolor/48x48/apps
icon22.files = desktop/desktop/22x22/cuteradio.png
icon22.path = /usr/share/icons/hicolor/22x22/apps
icon16.files = desktop/desktop/16x16/cuteradio.png
icon16.path = /usr/share/icons/hicolor/16x16/apps
target.path = /usr/bin
INSTALLS += \
desktop \
icon64 \
icon48 \
icon22 \
icon16
}
INSTALLS += target