build.gradle

apply plugin: 'base'

ext.getStringProperty = { name, defaultValue ->
    if (!project.hasProperty(name)) {
        return defaultValue
    }

    def propertyValue = project.getProperty(name)
    return propertyValue != null ? propertyValue.toString().trim() : defaultValue
}

subprojects {
    apply plugin: 'java'

    group = 'com.gluonhq.scenebuilder'
    version = project.findProperty('VERSION') ?: '8.5.0-SNAPSHOT'

    ext.buildDateFormat = version.endsWith('-SNAPSHOT') ? 'yyyy-MM-dd HH:mm:ss' : 'yyyy-MM-dd'

    repositories {
        maven {
            url "https://oss.sonatype.org/content/repositories/snapshots/"
        }
        maven {
            url "https://oss.sonatype.org/content/repositories/releases/"
        }
        maven {
            url "http://nexus.gluonhq.com/nexus/content/repositories/releases/"
        }

        jcenter()
        mavenCentral()
    }

    dependencies {
        // maven dependencies
        compile 'org.eclipse.aether:aether-api:1.1.0'
        compile 'org.eclipse.aether:aether-impl:1.1.0'
        compile 'org.eclipse.aether:aether-connector-basic:1.1.0'
        compile 'org.eclipse.aether:aether-transport-file:1.1.0'
        compile 'org.eclipse.aether:aether-transport-http:1.1.0'
        compile 'org.apache.maven:maven-aether-provider:3.3.9'

        compile 'com.gluonhq:charm-glisten:5.0.0'

        // REST API
        compile 'org.apache.httpcomponents:httpclient:4.5.2'
        compile 'javax.json:javax.json-api:1.0'
        runtime 'org.glassfish:javax.json:1.0.4'
        
        testCompile 'junit:junit:4.12'
        testCompile 'org.assertj:assertj-core:3.2.0'
    }

    test {
        // -PexcludeTests="Test1,Test2"
        if (project.hasProperty('excludeTests')) {
            project.properties['excludeTests']?.replaceAll(' ', '')?.split('[,;]')?.each {
                exclude "**/${it}.class"
            }
        }
    }
}

clean {
    delete "dist"
}

apply plugin: 'maven'

uploadArchives {
    repositories {
        mavenDeployer {
            def repoUrl = getStringProperty('publishRepositoryUrl', 'http://nexus.gluonhq.com/nexus/content/repositories/releases/');
            def repoUser = getStringProperty('publishRepositoryUser', '');
            def repoPassword = getStringProperty('publishRepositoryPassword', '');
            snapshotRepository(url: 'http://nexus.gluonhq.com/nexus/content/repositories/snapshots/') {
                authentication userName: repoUser, password: repoPassword
            }
            repository(url: repoUrl) {
                authentication(userName: repoUser, password: repoPassword);
            }
            addFilter('scenebuilder-all') { artifact, file ->
                artifact.name == 'scenebuilder-all'
            }
            addFilter('scenebuilder') { artifact, file ->
                artifact.name == 'scenebuilder'
            }
            pom('scenebuilder-all') {
                artifactId = 'scenebuilder-all'
            }
        }
    }
}