Merge pull request #43 from silinternational/develop

Release 3.6.0 - Redis

aws/ecs/service-no-alb/README.md

@@ -13,6 +13,7 @@ This module is used to create an ECS service as well as task definition
  - `service_env` - Name of environment, used in naming task definition. Ex: `staging`
  - `container_def_json` - JSON for container definition.
  - `desired_count` - Number of tasks to run in service
+ - `volumes` - A list of volume definitions in JSON format that containers in your task may use
 
 ### Optional Inputs
 
@@ -41,5 +42,17 @@ module "ecsservice" {
   service_env        = "${var.app_env}"
   container_def_json = "${file("task-definition.json")}"
   desired_count      = 2
+
+  volumes = [
+    {
+      name                     = "vol_name"
+      efs_volume_configuration = [
+        {
+          file_system_id = aws_efs_file_system.vol_name.id
+          root_directory = "/"
+        },
+      ]
+    },
+  ]
 }
 ```

aws/ecs/service-no-alb/main.tf

@@ -14,6 +14,33 @@ resource "aws_ecs_task_definition" "td" {
   container_definitions = var.container_def_json
   task_role_arn         = var.task_role_arn
   network_mode          = var.network_mode
+
+  dynamic "volume" {
+    for_each = var.volumes
+    content {
+      host_path = lookup(volume.value, "host_path", null)
+      name      = volume.value.name
+
+      dynamic "docker_volume_configuration" {
+        for_each = lookup(volume.value, "docker_volume_configuration", [])
+        content {
+          autoprovision = lookup(docker_volume_configuration.value, "autoprovision", null)
+          driver        = lookup(docker_volume_configuration.value, "driver", null)
+          driver_opts   = lookup(docker_volume_configuration.value, "driver_opts", null)
+          labels        = lookup(docker_volume_configuration.value, "labels", null)
+          scope         = lookup(docker_volume_configuration.value, "scope", null)
+        }
+      }
+
+      dynamic "efs_volume_configuration" {
+        for_each = lookup(volume.value, "efs_volume_configuration", [])
+        content {
+          file_system_id = lookup(efs_volume_configuration.value, "file_system_id", null)
+          root_directory = lookup(efs_volume_configuration.value, "root_directory", null)
+        }
+      }
+    }
+  }
 }
 
 /*

aws/ecs/service-no-alb/vars.tf

@@ -21,6 +21,12 @@ variable "desired_count" {
   type = string
 }
 
+variable "volumes" {
+  default     = []
+  description = "A list of volume definitions in JSON format that containers in your task may use"
+  type        = list(any)
+}
+
 /*
  * Optional Variables
  */

aws/elasticache/memcache/README.md

@@ -8,7 +8,7 @@ This module is used to create an Elasticache cluster of memcache servers
 
 ## Required Inputs
 
- - `cluster_id` - ID/Name for Elasticache Cluster
+ - `cluster_id` - ID/Name for Elasticache Cluster. Max 20 characters.
  - `security_group_ids` - List of security group IDs to place cluster in
  - `subnet_group_name` - Name of subnet group to create and place cluster in.
  - `subnet_ids` - List of subnet ids for subnet group.

aws/elasticache/memcache/main.tf

@@ -10,7 +10,7 @@ resource "aws_elasticache_subnet_group" "memcache_subnet_group" {
  * Create Cluster
  */
 resource "aws_elasticache_cluster" "memcache" {
-  cluster_id           = replace(var.cluster_id, "/(.{0,20})(.*)/", "$1")
+  cluster_id           = replace(var.cluster_id, "/(.{0,20})(.*)/", "$1") // truncates to maximum of 20 characters
   engine               = "memcached"
   node_type            = var.node_type
   port                 = var.port
@@ -25,4 +25,3 @@ resource "aws_elasticache_cluster" "memcache" {
     app_env  = var.app_env
   }
 }
-

aws/elasticache/redis/README.md

@@ -0,0 +1,45 @@
+# aws/ecs/elasticache/redis - Create a Elasticache cluster of Redis servers
+This module is used to create an Elasticache cluster of Redis servers
+
+## What this does
+
+ - Create Elasticache subnet group spanning all provided `var.subnet_ids`.
+ - Create Elasticache cluster of Redis servers.
+
+## Required Inputs
+
+ - `cluster_id` - ID/Name for Elasticache Cluster. Max 20 characters.
+ - `security_group_ids` - List of security group IDs to place cluster in
+ - `subnet_group_name` - Name of subnet group to create and place cluster in.
+ - `subnet_ids` - List of subnet ids for subnet group.
+ - `availability_zones` - List of availability zones to place cluster in.
+ - `app_name` - Application name to be tagged to cluster as `app_name`.
+ - `app_env` - Application environment to be tagged to cluster as `app_env`.
+
+### Optional Inputs
+
+ - `node_type` - Instance node type. Default: `cache.t2.micro`
+ - `port` - Redis port. Default: `6379`
+ - `parameter_group_name` - Name of Redis parameter group to use. Default: `default.redisd1.4`
+ - `engine_version` - Redis engine version. Default: `6.x`'
+
+## Outputs
+
+ - `cache_nodes` - List of cache nodes.
+ - `configuration_endpoint` - Redis configuration endpoint.
+ - `cluster_address` - DNS name for cache clusters without port.
+
+## Usage Example
+
+```hcl
+module "redis" {
+  source = "github.com/silinternational/terraform-modules//aws/elasticache/redis"
+  cluster_id = "doorman-cache"
+  security_group_ids = [module.vpc.vpc_default_sg_id]
+  subnet_group_name = "doorman-cache-subnet"
+  subnet_ids = module.vpc.private_subnet_ids
+  availability_zones = module.vpc.aws_zones
+  app_name = "doorman"
+  app_env = "staging"
+}
+```

aws/elasticache/redis/main.tf

@@ -0,0 +1,27 @@
+/*
+ * Create Elasticache subnet group
+ */
+resource "aws_elasticache_subnet_group" "redis_subnet_group" {
+  name       = var.subnet_group_name
+  subnet_ids = var.subnet_ids
+}
+
+/*
+ * Create Cluster
+ */
+resource "aws_elasticache_cluster" "redis" {
+  cluster_id           = replace(var.cluster_id, "/(.{0,20})(.*)/", "$1") // truncates to maximum of 20 characters
+  engine               = "redis"
+  engine_version       = var.engine_version
+  node_type            = var.node_type
+  port                 = var.port
+  num_cache_nodes      = "1"
+  parameter_group_name = var.parameter_group_name
+  security_group_ids   = var.security_group_ids
+  subnet_group_name    = aws_elasticache_subnet_group.redis_subnet_group.name
+
+  tags = {
+    app_name = var.app_name
+    app_env  = var.app_env
+  }
+}

aws/elasticache/redis/outputs.tf

@@ -0,0 +1,15 @@
+/*
+ * Cluster outputs
+ */
+output "cache_nodes" {
+  value = aws_elasticache_cluster.redis.cache_nodes
+}
+
+output "configuration_endpoint" {
+  value = aws_elasticache_cluster.redis.configuration_endpoint
+}
+
+output "cluster_address" {
+  value = aws_elasticache_cluster.redis.cluster_address
+}
+

aws/elasticache/redis/vars.tf

@@ -0,0 +1,52 @@
+/*
+ * Required Variables
+ */
+variable "cluster_id" {
+  type = string
+}
+
+variable "security_group_ids" {
+  type = list(string)
+}
+
+variable "subnet_group_name" {
+  type = string
+}
+
+variable "subnet_ids" {
+  type = list(string)
+}
+
+variable "availability_zones" {
+  type = list(string)
+}
+
+variable "app_name" {
+  type = string
+}
+
+variable "app_env" {
+  type = string
+}
+
+/*
+ * Optional Variables
+ */
+variable "node_type" {
+  type    = string
+  default = "cache.t2.micro"
+}
+
+variable "port" {
+  type    = string
+  default = "6379"
+}
+
+variable "parameter_group_name" {
+  type    = string
+  default = "default.redis6.x"
+}
+
+variable "engine_version" {
+  default = "6.x"
+}

aws/elasticache/redis/versions.tf

@@ -0,0 +1,4 @@
+
+terraform {
+  required_version = ">= 0.12"
+}